dev-qt/qtlocation: 5.15.9 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

dev-qt/qtlocation/Manifest

@@ -1,2 +1,5 @@
 DIST qtlocation-5.15.8-gentoo-kde-1.tar.xz 3952 BLAKE2B 6084d14533ca2ba44249db817f1f0bb93e526fc14e4f4f32d9c99f7b231e25449b111bf9e08b8dca95928d3ac29f63a8e42cbd51d9cd0700344aad6982dd2ff9 SHA512 868e96a2a84bfb0e068957968c07b3558bef2c12517c5971b11e1b536a92ae80d0ca399355f8fadc0fcef2b272b77e6b30951f96ec7fbe174bb5a053567d2c9e
+DIST qtlocation-5.15.9-gentoo-kde-1.tar.xz 3968 BLAKE2B a36b202400894ea4b5f377381a5870e88022c5a20e1adec4515745bc2606b7f0180ff30435724218c0f1ef130cbf29f57a0c6c7f4f48b9b3689c7aa8bb2bfa73 SHA512 e043e0537ecb66372b9464fd2d49bc8d6297bb29e5ceddc171d3899fd42a57cf129782c85efab6d5d3bc7dc3db91ba623161f7369861e9a7b6623e557dd8834e
 DIST qtlocation-everywhere-opensource-src-5.15.8.tar.xz 6559180 BLAKE2B 1b8feb5da8d564a6605d9106ec6399aea23a4f0b43f495baf61e14266e90d2d73cd310fb6d8514730867acba1aa26efb3072c213f22f19f72c2f554d76ab281b SHA512 a337fade917150c13fa2ea22ad1949f41541cea4ceb1f732ab53c20c2f19a63dcfc6f9f544ca64fdb5703d3ac8d2ec6e832f1f199a32e73a2f6c51febf53f514
+DIST qtlocation-everywhere-opensource-src-5.15.9.tar.xz 6552244 BLAKE2B 5091aef5706313660dd6fe5d831d0a9b8b6160739c1cce115e6a42a0b2ff3020ff0cd51a99bff9d24ccd29952b259fd1953bd5691ae4c3b2cbb8f31d3e9107f8 SHA512 37517c304240921c600e2aad19baff0efbb5e01c5cc78e5370fb4b084f2a6ba4da94d39ddcbcd33a5f0af37f017d39bb775a40cda195e16697aa70c9d17b6bcf
+DIST qtlocation-mapboxgl-5.15.9-5a07e196.tar.gz 3726230 BLAKE2B 9dbe08088a55bc1da4952a628af987b3b056615e883983d3a5e2eb392ce4aff16bfd753f84bbad07f9a415fbd275ec9933a64b6bcfd27ea6d8adced6d2adcac7 SHA512 ec3de81f643388690eda45d073a9c6f908d8efeff30cd062d9afcd1f94c6b45b301327747928d45b4047ce04b7df5b0afaf9e8942e22660711a5ac49787829eb

dev-qt/qtlocation/qtlocation-5.15.9.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=1
+	MAPBOXGL_COMMIT=5a07e1967dcc925d9def47accadae991436b9686
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+inherit qt5-build
+
+DESCRIPTION="Location (places, maps, navigation) library for the Qt5 framework"
+[[ ${QT5_BUILD_TYPE} == release ]] &&
+SRC_URI+=" https://invent.kde.org/qt/qt/${PN}-mapboxgl/-/archive/${MAPBOXGL_COMMIT}/${PN}-mapboxgl-${MAPBOXGL_COMMIT}.tar.gz -> ${PN}-mapboxgl-${PV}-${MAPBOXGL_COMMIT:0:8}.tar.gz"
+
+IUSE=""
+
+RDEPEND="
+	dev-libs/icu:=
+	=dev-qt/qtcore-${QT5_PV}*
+	=dev-qt/qtdeclarative-${QT5_PV}*
+	=dev-qt/qtgui-${QT5_PV}*
+	=dev-qt/qtnetwork-${QT5_PV}*
+	=dev-qt/qtpositioning-${QT5_PV}*[qml]
+	=dev-qt/qtsql-${QT5_PV}*
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	=dev-qt/qtconcurrent-${QT5_PV}*
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/3rdparty/clipper
+	src/3rdparty/poly2tri
+	src/3rdparty/clip2tri
+	src/3rdparty/mapbox-gl-native
+	src/location
+	src/imports/location
+	src/imports/locationlabs
+	src/plugins/geoservices
+)
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+src_prepare() {
+	rm -rf src/3rdparty/mapbox-gl-native/* || die
+	mv "${WORKDIR}"/${PN}-mapboxgl-${MAPBOXGL_COMMIT}/* src/3rdparty/mapbox-gl-native || die
+	qt5-build_src_prepare
+}
+fi
+
+src_configure() {
+	# src/plugins/geoservices requires files that are only generated when
+	# qmake is run in the root directory. Bug 633776.
+	mkdir -p "${QT5_BUILD_DIR}"/src/location || die
+	qt5_qmake "${QT5_BUILD_DIR}"
+	cp "${S}"/src/location/qtlocation-config.pri "${QT5_BUILD_DIR}"/src/location || die
+	qt5-build_src_configure
+}