dev-util/azuredatastudio: new package; add 1.47.0

Signed-off-by: Maciej Barć <[email protected]>

dev-util/azuredatastudio/Manifest

@@ -0,0 +1 @@
+DIST azuredatastudio-1.47.0-amd64.deb 138852252 BLAKE2B 20598aefb8ade4f1022213de1dfa17feddfb41ee0a241f8e9919e7573d00f3c3f81bbab947c9fec885a08b1e032a61616b1f49b943f3388c1edeb5502717e773 SHA512 7de1f1bafee735cfe7d52cb32324e38497ccb919a6322463b60bf2002af64546972f4ed207fdf0d9e55c48e33d7f5d7a9a3d10781c9c458edd4d18880ee5d310

dev-util/azuredatastudio/azuredatastudio-1.47.0.ebuild

@@ -0,0 +1,101 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit unpacker xdg
+
+DESCRIPTION="Data management and development tool from Microsoft"
+HOMEPAGE="https://vscodium.com/"
+SRC_URI="
+	amd64? (
+		https://azuredatastudio-update.azurewebsites.net/${PV}/linux-deb-x64/stable
+			-> ${P}-amd64.deb
+	)
+"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="kerberos"
+RESTRICT="bindist"
+
+# This is based on VSCode/VSCodium, so just copy their "RDEPEND".
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret[crypt]
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/libcanberra[gtk3]
+	media-libs/libglvnd
+	media-libs/mesa
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/zlib
+	sys-process/lsof
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libnotify
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	x11-misc/xdg-utils
+	kerberos? ( app-crypt/mit-krb5 )
+"
+DEPEND="
+	dev-libs/openssl-compat:1.0.0
+"
+BDEPEND="
+	dev-util/patchelf
+"
+
+QA_PREBUILT="*"
+
+src_unpack() {
+	unpack_deb "${A}"
+}
+
+src_prepare() {
+	default
+
+	cd "${S}/usr/share" || die
+
+	mv appdata metainfo || die
+	mv zsh/vendor-completions zsh/site-functions || die
+
+	cd "${PN}" || die
+
+	# Kerberos libs, same issue as VSCode/VSCodium.
+	if ! use kerberos ; then
+		rm -r resources/app/node_modules.asar.unpacked/kerberos || die
+	fi
+
+	# Patch "System.Security.Cryptography.Native.OpenSsl.so": *.so.10 -> *.so.1.0.0
+	local lib=System.Security.Cryptography.Native.OpenSsl.so
+	cd resources/app/extensions/mssql/sqltoolsservice/Linux/4.10.1.3 || die
+	patchelf --add-needed libcrypto.so.1.0.0 "${lib}" || die
+	patchelf --add-needed libssl.so.1.0.0 "${lib}" || die
+	patchelf --remove-needed libcrypto.so.10 "${lib}" || die
+	patchelf --remove-needed libssl.so.10 "${lib}" || die
+}
+
+src_install() {
+	cp -r . "${ED}" || die
+
+	dosym -r "/usr/share/${PN}/${PN}" "/usr/bin/${PN}"
+}

dev-util/azuredatastudio/metadata.xml

@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="person">
+    <email>[email protected]</email>
+    <name>Maciej Barć</name>
+  </maintainer>
+  <longdescription>
+    Azure Data Studio is a data management and development tool with
+    connectivity to popular cloud and on-premises databases. Azure Data Studio
+    supports Windows, macOS, and Linux, with immediate capability to connect to
+    Azure SQL and SQL Server. Browse the extension library for more database
+    support options including MySQL, PostgreSQL, and MongoDB.
+  </longdescription>
+  <upstream>
+    <bugs-to>https://github.com/microsoft/azuredatastudio/</bugs-to>
+    <remote-id type="github">microsoft/azuredatastudio</remote-id>
+  </upstream>
+</pkgmetadata>