app-cdr/dolphin-plugins-mountiso: 21.04.2 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

app-cdr/dolphin-plugins-mountiso/Manifest

@@ -1,2 +1,3 @@
 DIST dolphin-plugins-20.12.3.tar.xz 239340 BLAKE2B 141e5d2bb6190edaef98cec2a271e41b916966118300d69f4eb5e7da15e51730476f23a20312b76fca0fc1490501e83528b4f0cb62f9f6c64e4caf5ac5b2cd37 SHA512 1d5303e92d912bc80c5260263b081205d36372f1f15205ebd3e705697a114f8481edd1ad31004d7906c3088d43a74cb1e33dac6e1196c247e702a544d67db11b
 DIST dolphin-plugins-21.04.1.tar.xz 247356 BLAKE2B 9dae16c07b7f1bf1bc3d33f2a9b32f52f18efb5cb73e82f4b35099dc38b9ecb31a1ec7f06c403d498b7f8f949de23f4ba2289c9efb7f67c19bff6d59595bafe9 SHA512 62ccbc3d8870f3352073299762d4ec6b8faf15a77a3530a6a93562ee776aded3a73a4d767523371c22fb7dec6c2ec8a1e9263ba2399a8fee7b20fc14c10ecf3a
+DIST dolphin-plugins-21.04.2.tar.xz 253184 BLAKE2B 2ca0bdbdd1e658bd54a95790d722e23817aca2af1bff16b5056686e58b5ce60aeaecba05ec3a2faf69ccf4d1c4dd7ee91f59cec37da3693917ed9144c4e48ae2 SHA512 379e87f0ee28dd414c1ffe1f2e7775681cf639cda72a6357c357f2a7a30aefee77cfc8b52cb4030ff68555a38d0abf428ac155cbd2d3263ac55b4f41b9ae1fda

app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.04.2.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_GEAR="true"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.80.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}