app-i18n/sunpinyin: Version bump (2.0.4_pre20200306162733).

Bug: https://bugs.gentoo.org/695010
Bug: https://bugs.gentoo.org/695022
Signed-off-by: Arfrever Frehtes Taifersar Arahesis <[email protected]>
Signed-off-by: Mike Gilbert <[email protected]>

app-i18n/sunpinyin/Manifest

@@ -1,2 +1,3 @@
 DIST sunpinyin-2.0.4_pre20130108.tar.xz 964764 BLAKE2B 2c9d2e3fc02009ad10784c9408434c6806d1403026fb27629701650fe0e8a69c5580050846cf5c3b870215b8bfd68fe9c52d8bdaf83c41e523224463af9cf530 SHA512 7c1dd7db8b800e9d436746a560a16de2c6777576868f2e7e28f6dcb767b91ccd62b974f9d4ce6bd6ce80d30e1ee83887c3ee03c227e7e9fa59c01db4867465b2
+DIST sunpinyin-2.0.4_pre20200306162733.tar.gz 547519 BLAKE2B 6e0e4457217d7b85221cab15173f588a5c7c039208a8f6cd48ed5fb21c5b5eae2f4616d6fddbf6eff8a006193097de26c866d5385d4602f41059ee8d7e52a2d5 SHA512 e8cf73aeca8dcbc7dd6f51f034a9a0363201bc14a814800e071c987933935b0e8039aa84178a6bd1cba1c7dee4b25b2d5546e78ea683e68e8981afea48fdab33
 DIST sunpinyin-3.0.0_rc1.tar.gz 547138 BLAKE2B 682e733241d690d1fef8ce452c497a894c5ab61bf5298c1f292ce3a25a681d594744db43ebd51b3e59274cce0e47a1bce15a793f2c20e2998915c3432f2a7c32 SHA512 c9d4936de5835a7f02e52c5b32bf1a42d76bf7588449aaa813f3df7ab2d72f3ca0f4e18f74a60be4860f0724b5e05cbe567c67e6f3150b0e71b23b3a9002fc5e

app-i18n/sunpinyin/sunpinyin-2.0.4_pre20200306162733.ebuild

@@ -0,0 +1,64 @@
+# Copyright 2009-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{3_6,3_7,3_8})
+
+inherit python-any-r1 scons-utils toolchain-funcs
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/sunpinyin/sunpinyin"
+elif [[ "${PV}" == *_pre* ]]; then
+	SUNPINYIN_GIT_REVISION="f39c195db08661e894017507842991a1ef70bedf"
+fi
+
+DESCRIPTION="Statistical Language Model (SLM) based Chinese input method library"
+HOMEPAGE="https://github.com/sunpinyin/sunpinyin"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+elif [[ "${PV}" == *_pre* ]]; then
+	SRC_URI="https://github.com/sunpinyin/${PN}/archive/${SUNPINYIN_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+else
+	SRC_URI="https://github.com/sunpinyin/${PN}/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="|| ( CDDL LGPL-2.1 )"
+SLOT="0/3"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	dev-lang/perl
+	virtual/pkgconfig"
+DEPEND="dev-db/sqlite:3"
+RDEPEND="${DEPEND}"
+
+if [[ "${PV}" == *_pre* ]]; then
+	S="${WORKDIR}/${PN}-${SUNPINYIN_GIT_REVISION}"
+elif [[ "${PV}" != "9999" ]]; then
+	S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+src_prepare() {
+	default
+	sed -e "/^docdir =/s:/sunpinyin:/${PF}:" -i SConstruct || die
+
+	# https://github.com/sunpinyin/sunpinyin/issues/109
+	sed -e "/^Requires: sqlite3$/s/^Requires:/Requires.private:/" -i sunpinyin-2.0.pc.in || die
+}
+
+src_configure() {
+	tc-export CXX
+}
+
+src_compile() {
+	escons \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)"
+}
+
+src_install() {
+	escons --install-sandbox="${D}" install
+}