www-misc/monitorix: Version bump to 3.6.0

Version bump to 3.6.0.
Updated SRC_URI to use GitHub repo.

Package-Manager: portage-2.2.26
Closes: gentoo#1269

Signed-off-by: Ian Delaney <[email protected]>

www-misc/monitorix/Manifest

@@ -1 +1,2 @@
 DIST monitorix-3.5.1.tar.gz 218548 SHA256 8cbd749153f48e17a253791c2079912e50b499026de0083e5f25b87a782f3004 SHA512 cf64f89e147f3ddf31d48e593d5a5f09be827fd9a104c5cc28b1146e491507476d4f86bf249fda24ce92d7e37a3699dd94501d441c3767d12dfbabe4d782c37c WHIRLPOOL 2b894222f4defd5396c9c82554caeaccdcb64dd387dd78a0f2beabf896c6fedbf4571b2f2822786b2dc4165946588f72b5d4e1f6f5d2f4acde17beddd57ceab7
+DIST monitorix-3.6.0.tar.gz 229824 SHA256 0e9976a61f5d4ab787a69dc4ccf7cc4d03ff9db0afaa19790a4d29a67c3f0db2 SHA512 84525ba7eb6b6c225f4aace836795a17e51c59b14b328ab4fb0fd1fc5f78e5ec7f227c1c7ac7857b0a1f2d6d979feca2b445921da5f88bc6a9b5bdbef5d1e82b WHIRLPOOL df5b89e83e58bd1d5ddbebc1c909da10aa27c56828fc287ac0b79f231541839079aad9147562d5428d3b1dff815faa41991963cc2beb7160c474a1bbe52bd531

www-misc/monitorix/monitorix-3.6.0.ebuild

@@ -0,0 +1,95 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils systemd user
+
+DESCRIPTION="A lightweight system monitoring tool"
+HOMEPAGE="http://www.monitorix.org/"
+SRC_URI="https://github.com/mikaku/Monitorix/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="apcupsd hddtemp httpd lm_sensors postfix"
+S="${WORKDIR}/Monitorix-${PV}"
+
+DEPEND="sys-apps/sed"
+RDEPEND="dev-perl/Config-General
+	dev-perl/DBI
+	dev-perl/HTTP-Server-Simple
+	dev-perl/IO-Socket-SSL
+	dev-perl/libwww-perl
+	dev-perl/MIME-Lite
+	dev-perl/XML-Simple
+	net-analyzer/rrdtool[graph,perl]
+	dev-perl/CGI
+	apcupsd? ( sys-power/apcupsd )
+	hddtemp? ( app-admin/hddtemp )
+	httpd? ( virtual/httpd-cgi )
+	lm_sensors? ( sys-apps/lm_sensors )
+	postfix? ( net-mail/pflogsumm dev-perl/MailTools )"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+}
+
+src_prepare() {
+	# Put better Gentoo defaults in the configuration file.
+	sed -i "s|\(base_dir.*\)/usr/share/${PN}|\1/usr/share/${PN}/htdocs|" ${PN}.conf
+	sed -i "s|\(secure_log.*\)/var/log/secure|\1/var/log/auth.log|" ${PN}.conf
+	sed -i "s|nobody|${PN}|g" ${PN}.conf
+}
+
+src_install() {
+	dosbin ${PN}
+
+	newinitd "${FILESDIR}"/${PN}.init ${PN}
+
+	insinto /etc/monitorix
+	doins ${PN}.conf
+
+	dodir /etc/${PN}/conf.d
+
+	insinto /etc/logrotate.d
+	newins docs/${PN}.logrotate ${PN}
+
+	dodoc Changes README{,.nginx} docs/${PN}.service docs/${PN}-{alert.sh,apache.conf,lighttpd.conf}
+	doman man/man5/${PN}.conf.5
+	doman man/man8/${PN}.8
+
+	insinto /var/lib/${PN}/www
+	doins logo_bot.png logo_top.png ${PN}ico.png
+
+	dodir /var/lib/${PN}/www/imgs
+
+	exeinto /var/lib/${PN}/www/cgi
+	doexe ${PN}.cgi
+
+	dodir /usr/lib/${PN}
+	exeinto /usr/lib/${PN}
+	doexe lib/*.pm
+
+	dodir /var/lib/${PN}/usage
+	insinto /var/lib/${PN}/reports
+	doins -r reports/*
+
+	systemd_dounit docs/${PN}.service
+}
+
+pkg_postinst() {
+	chmod 777 /var/lib/${PN}/www/imgs
+	elog "WARNING: ${PN} has changed its config format twice, in versions"
+	elog "3.0.0 and 3.4.0; this format may be incompatible with your existing"
+	elog "config file. Please take care if upgrading from an old version."
+	elog ""
+
+	elog "${PN} includes its own web server as of version 3.0.0."
+	elog "For this reason, the dependency on the webapp framework"
+	elog "has been removed. If you wish to use your own web server,"
+	elog "the ${PN} web data can be found at:"
+	elog "/var/lib/${PN}/www/"
+}