www-client/falkon: 22.08.0 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

www-client/falkon/Manifest

@@ -1,2 +1,3 @@
 DIST falkon-22.04.3.tar.xz 2492448 BLAKE2B c7b2bbe9a7b3a55078faa5d7706ebe5df279c3ffd618a064b7707a7636f1436779e7cbb89bda5e012e4d9982e8ffc29d01be8436f9d483fdd2c3f67a19f92cfc SHA512 174725086360f0109fb70bf7056c9cfa122a114aecf00bbe27a47c5f23cca76b69c41a2e15f077fd27cff726317f40be08e296ed249dbd73036a89502823d23b
+DIST falkon-22.08.0.tar.xz 2498728 BLAKE2B d3aa3c3d77e24e13ef2af22913126e81f1ead1201d5eeb88fb66d26108983451895623e8c7c7c5d545cdf85ec9188b475f51366528ab346cecc79e38c0c63326 SHA512 1933a53b395a5c4bde977de014c6d4363fce03d048faa5d35aae85a1349ad455daef4023eaf2da9d0f9c3cb8bcab557ef212aa022148a1cce4a9f4c657b5e9ab
 DIST falkon-3.2.0.tar.xz 2506692 BLAKE2B a94118e2bd8e97e00a5462d657ee07c06aed53f5bee21227f543f902588f68588c0f4e445bb5cae789d14dec25382802025f502138150db96fe636b20d257222 SHA512 1bc33a957dd265b3cdd944f85890500c7247d82752cc7d6847c61de2f810e75d10adddf81dc6bcb1e05e1cd3bda04767c66f1e16d7ed19634e3b80ad24ff6bc1

www-client/falkon/falkon-22.08.0.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.96.0
+QTMIN=5.15.5
+PYTHON_COMPAT=( python3_{8..11} )
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+ dev-libs/openssl:0=
+ >=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+ >=dev-qt/qtprintsupport-${QTMIN}:5
+ >=dev-qt/qtsql-${QTMIN}:5[sqlite]
+ >=dev-qt/qtwebchannel-${QTMIN}:5
+ >=dev-qt/qtwebengine-${QTMIN}:5=[widgets]
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=kde-frameworks/karchive-${KFMIN}:5
+ virtual/libintl
+ dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+ kde? (
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kcrash-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/kwallet-${KFMIN}:5
+ >=kde-frameworks/purpose-${KFMIN}:5
+ )
+ python? (
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep "
+ >=dev-python/pyside2-${QTMIN}[designer,gui,webengine,widgets,\${PYTHON_USEDEP}] \
+ >=dev-python/shiboken2-${QTMIN}[\${PYTHON_USEDEP}]
+ ")
+ )
+ X? (
+ >=dev-qt/qtx11extras-${QTMIN}:5
+ x11-libs/libxcb:=
+ x11-libs/xcb-util
+ )
+"
+DEPEND="${COMMON_DEPEND}
+ >=dev-qt/qtconcurrent-${QTMIN}:5
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+ DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:5"
+fi
+RDEPEND="${COMMON_DEPEND}
+ >=dev-qt/qtsvg-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+PATCHES=( "${FILESDIR}/${PN}-22.04.3-python3.patch" )
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+ ecm_pkg_setup
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_KEYRING=OFF
+ -DDISABLE_DBUS=$(usex !dbus)
+ $(cmake_use_find_package kde KF5Wallet)
+ $(cmake_use_find_package kde KF5KIO)
+ $(cmake_use_find_package python PySide2)
+ $(cmake_use_find_package python Shiboken2)
+ $(cmake_use_find_package python Python3)
+ -DNO_X11=$(usex !X)
+ )
+ use python && mycmakeargs+=(
+ -DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+ -DPython3_INCLUDE_DIR=$(python_get_includedir)
+ -DPython3_LIBRARY=$(python_get_library_path)
+ )
+ ecm_src_configure
+}