gui-apps/swayidle: 1.7 bump

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Matthew Thode <[email protected]>

gui-apps/swayidle/Manifest

@@ -1 +1,2 @@
 DIST swayidle-1.6.tar.gz 10131 BLAKE2B c0391d288c780c61b72b7a5ac612efc18c359cc7d622faa308e22b1e4359c064bc2824e7cb8fc14143ddde54fc6980bdc5d449d1f16a867b54aef9dfbaa4ff17 SHA512 c82b0d2aee06f87fd71e9e2208e917c0dc7afe80ab0b782c3165127519445021d8cf363292eee99f939165eb813909f2a4ee74153e776557c6d06672de2c1c82
+DIST swayidle-1.7.tar.gz 12458 BLAKE2B 06462d286e4786173d26241056c2b0c71a9253eac31e0b33bd70c5729ff172c3b8ab2c6377c3bc4a6f53cf580adbaac792d90f46da7f944bcc5a4055b642fe5a SHA512 26a48c510caaadb1ad694426e82880ab1547b7b0ef8ac62a2c2ee41c7b8cc0554f4925b0abdc6dc37f2501a171c0b6ae53c56b045b5c545093f3b0463aefcf24

gui-apps/swayidle/swayidle-1.7.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Idle management daemon for Wayland"
+HOMEPAGE="https://github.com/swaywm/swayidle"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind +man systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	dev-libs/wayland
+	elogind? ( >=sys-auth/elogind-237[policykit] )
+	systemd? ( >=sys-apps/systemd-237[policykit] )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		"-Dfish-completions=true"
+		"-Dzsh-completions=true"
+		"-Dbash-completions=true"
+		"-Dwerror=false"
+	)
+	if use systemd; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd")
+	elif use elogind; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind")
+	else
+		emesonargs+=("-Dlogind=disabled")
+	fi
+
+	meson_src_configure
+}