app-cdr/dolphin-plugins-mountiso: 21.08.2 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

app-cdr/dolphin-plugins-mountiso/Manifest

@@ -1,2 +1,3 @@
 DIST dolphin-plugins-21.04.3.tar.xz 253244 BLAKE2B c5c0e302dfc4eb82e2de1a635824bf8fd2c70bcac65c261253f0e52e7d9242fa339fe2dc619b927b0379477b2c80a22ec210080af8f2370e0a0182af3347df6a SHA512 e4beba0d596782951b149d42e930d76b12a36bea83f35eb0cff9e49b3e02d4b2aa55f4245d4b8708044a49770d477badc964752828eef4caeaefd4f16e5f9dad
 DIST dolphin-plugins-21.08.1.tar.xz 252604 BLAKE2B 9828c3cf690ce54d9ee0be682b7ebf6ac3bd1ec9fd5f73e14c355cf10a19e7e882d3b1a2f3fbdadec8b1f8df926c8bffd566b0cf53a0dafe126b7b70a80ebe6e SHA512 71c0aa8f8207018192853714ca6612f7b56fed9b78d67f940381716ffe60357108a6993326ba67113f66783795d18fd5a68b3bc69b8c449da750d0316e091b52
+DIST dolphin-plugins-21.08.2.tar.xz 253236 BLAKE2B a574e684b7433ea611994ea77ac1b70650760d39d5015cf364a684d4da2b7d7b1ba739f66856c15c3bb9b8d8cf58b2e652762c9844c7af3a2cd983ae8d60727f SHA512 b7b16188dc649b86ffb39d948613b30ad77a3d941706d746bf81609ffa74bc75479abbaa4e5010abf1715cbf52d490145c65398ca91fadd5c31f330f4a1b9f1e

app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.08.2.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_GEAR="true"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.84.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=kde-apps/dolphin-${PVCUT}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/ktextwidgets-${KFMIN}:5
+ >=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+ ecm_src_prepare
+ # kxmlgui, qtnetwork only required by dropbox
+ ecm_punt_bogus_dep Qt5 Network
+ ecm_punt_bogus_dep KF5 XmlGui
+ # delete non-${PN} translations
+ if [[ ${KDE_BUILD_TYPE} = release ]]; then
+ find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_${MY_PLUGIN_NAME}=ON
+ -DBUILD_bazaar=OFF
+ -DBUILD_dropbox=OFF
+ -DBUILD_git=OFF
+ -DBUILD_hg=OFF
+ -DBUILD_svn=OFF
+ )
+ ecm_src_configure
+}
+
+src_install() {
+ ecm_src_install
+ rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}