media-video/unifi-video: bump to 3.9.8_beta1 (unkeyworded)

Package-Manager: Portage-2.3.44, Repoman-2.3.10

media-video/unifi-video/Manifest

@@ -1 +1,2 @@
 DIST unifi-video.Ubuntu16.04_amd64.v3.9.7.deb 117374890 BLAKE2B b0f274da3052471472cd2405ec0a5d79fd97cbc30f014ede42a004dcffc4d27b9b5ecc36f32b4f60f8c47ba73b85795d2851345f5472b85192cf836bfb929173 SHA512 9a0f48d81f3935baad4004681cabe2ff46f4f86f8770c260c98fbd724de2949427de8ec706d86d612a9ccbcda69ca227aa4a123c3208e0a4ab7c0a51540c06f8
+DIST unifi-video.Ubuntu16.04_amd64.v3.9.8-beta.1.deb 117380976 BLAKE2B 7fea704c3b780d51c3d0fc1de24b74654ba438b5223b368bbd6b42110b98fb22f0aa29816b6acec9961a9fa4f6dbace54361c64c4c12ae6a39b855c9e91702a1 SHA512 a4782c3b5319d7bc54d5df3dc64fdfec86e729636cc2e5479d7ca3a8f5112c57c83c0ac421be3cc0ce88975d6f47dd7bb57743d6802164531fdafed2bbe484bb

media-video/unifi-video/unifi-video-3.9.8_beta1.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit systemd user
+
+MY_PV="${PV/_beta/-beta.}"
+DESCRIPTION="UniFi Video Server"
+HOMEPAGE="https://www.ubnt.com/download/unifi-video/"
+SRC_URI="https://dl.ubnt.com/firmwares/ufv/v${MY_PV}/unifi-video.Ubuntu16.04_amd64.v${MY_PV}.deb"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+IUSE=""
+RESTRICT="mirror"
+
+DEPEND=""
+RDEPEND="dev-db/mongodb
+	dev-java/commons-daemon
+	sys-apps/lsb-release
+	sys-libs/libcap
+	virtual/jre:1.8"
+
+S=${WORKDIR}
+QA_PREBUILT="/usr/lib*/${PN}/lib/*.so /usr/lib*/${PN}/bin/*"
+
+pkg_setup() {
+	enewuser ${PN}
+	enewgroup ${PN}
+}
+
+src_unpack() {
+	default
+	unpack "${WORKDIR}"/data.tar.gz
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/commons-daemon-move.patch
+	sed -i usr/sbin/${PN} \
+		-e '/require_root$/d' \
+		-e '/update_limits$/d' \
+		-e '/ulimit/d' \
+		-e '/coredump_filter/d' || die
+	default
+}
+
+src_install() {
+	static_dir="/usr/$(get_libdir)/${PN}"
+	#install static data
+	insinto ${static_dir}
+	doins -r usr/lib/${PN}/*
+	fperms -R +x ${static_dir}/bin
+	fowners -R ${PN}:${PN} ${static_dir}/conf/evostream/
+
+	#wrapper to work around mongodb-3.6 compat issue
+	exeinto ${static_dir}/bin/
+	newexe "${FILESDIR}"/mongod-wrapper mongod
+
+	#prepare runtime-data dirs which live in /var but are symlinked from static
+	#data dir, and are writable by non-root user
+	dodir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+	dosym ../../../var/log/${PN} ${static_dir}/logs
+
+	dodir /var/lib/${PN}/work
+	fowners ${PN}:${PN} /var/lib/${PN}/work
+	dosym ../../../var/lib/${PN}/work ${static_dir}/work
+
+	keepdir /var/lib/${PN}/data
+	fowners ${PN}:${PN} /var/lib/${PN}/data
+	dosym ../../../var/lib/${PN}/data ${static_dir}/data
+
+	echo "CONFIG_PROTECT=\"/var/lib/${PN}/data/system.properties\"" > "${T}"/99${PN}
+	doenvd "${T}"/99${PN}
+
+	into /usr
+	dosbin usr/sbin/${PN}
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+}