app-admin/mcelog: Version bump to 157

app-admin/mcelog/Manifest

@@ -1 +1,2 @@
 DIST mcelog-154.tar.gz 297148 BLAKE2B 80b2b6b13222d0194d63516607b3132e2146894189e2c3c793c953dc43705a5b386ecb76ae3c8b7b345f8d440f547b3e566b16bf0802d17188cce978e1ad2fc1 SHA512 8a160aaa8a0ed736cb81082321e199e6a6e4f7f6528915752af545db28918e89dcb6bf321a92472d776c61914d08c613900273b3d265a375684e3212547abe38
+DIST mcelog-157.tar.gz 297194 BLAKE2B f34e57f282828941b7023b6f043084dec4591b071f4e23fff318ea4ff49c8be2c0eab3279d7803d3cf029351f51d2acdf16d4eb1998042a8002f6667c81df90d SHA512 831835058ab820497aed5640a424908e3ee138431041b1c70e2d4f601a242e0437d240a842de1c0bc10f41790f1ddff64054e79ff2a6de1c814710acd9210bbd

app-admin/mcelog/mcelog-157.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit linux-info systemd toolchain-funcs
+
+DESCRIPTION="A tool to log and decode Machine Check Exceptions"
+HOMEPAGE="http://mcelog.org/"
+SRC_URI="https://github.com/andikleen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-mcelog )"
+
+# TODO: add mce-inject to the tree to support test phase
+RESTRICT="test"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != buildonly ]]; then
+		local CONFIG_CHECK="~X86_MCE"
+		kernel_is -ge 4 12 && CONFIG_CHECK+=" ~X86_MCELOG_LEGACY"
+		check_extra_config
+	fi
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-0.8_pre1-timestamp-${PN}.patch \
+		"${FILESDIR}"/${PN}-129-debugflags.patch
+	eapply_user
+	tc-export CC
+}
+
+src_install() {
+	default
+
+	insinto /etc/cron.daily
+	newins ${PN}.cron ${PN}
+
+	insinto /etc/logrotate.d/
+	newins ${PN}.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}.init-r1 ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	dodoc *.pdf
+}
+
+pkg_postinst() {
+	einfo "The default configuration set is now installed in /etc/${PN}"
+	einfo "you might want to edit those files."
+	einfo
+	einfo "A sample cronjob is installed into /etc/cron.daily"
+	einfo "without executable bit (system service is the preferred method now)"
+}