dev-util/clion: version bump to 2021.1

Package-Manager: Portage-3.0.17-r2, Repoman-3.0.2
Signed-off-by: Christian Strahl <[email protected]>
Signed-off-by: Joonas Niilola <[email protected]>

dev-util/clion/Manifest

@@ -1 +1,2 @@
 DIST CLion-2020.3.3.tar.gz 624552270 BLAKE2B 46290e8419e9cdfb9321a5364316447863301e69446994737972af18547a0306a82af3f407d07a043591faafe528fd09d9e18b7f76f610597f7781dcba9478ea SHA512 e0ea848a4a8b07ceb6bd60b6c57163cd3dabbca336a72e3618e15adcf011c5df7b34e43126d668a9c1b3ce15dfecfa905da3c1fd77bcdd209d9eccc87360cf1d
+DIST CLion-2021.1.tar.gz 711517491 BLAKE2B b5ae7b1337f24b0d1ce738624dd15d03f3770ec9af830b0f932c8abc46c60992e52bb0f77e80c03cd922f7873f77e89042c20e09640f052a7bd7523784b226ce SHA512 a916f270b7f9471926500814979b23aab4903d681c6c0a907ce8c3874fdf65d75f0d9d1b2c9477bba60a06e22ecb73ca0204bb7470a5b85577ee40ad23306da6

dev-util/clion/clion-2021.1.ebuild

@@ -0,0 +1,105 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop wrapper
+
+DESCRIPTION="A complete toolset for C and C++ development"
+HOMEPAGE="https://www.jetbrains.com/clion"
+SRC_URI="https://download.jetbrains.com/cpp/CLion-${PV}.tar.gz"
+
+LICENSE="|| ( IDEA IDEA_Academic IDEA_Classroom IDEA_OpenSource IDEA_Personal )
+	Apache-1.1 Apache-2.0 BSD BSD-2 CC0-1.0 CDDL-1.1 CPL-0.5 CPL-1.0
+	EPL-1.0 EPL-2.0 GPL-2 GPL-2-with-classpath-exception GPL-3 ISC JDOM
+	LGPL-2.1+ LGPL-3 MIT MPL-1.0 MPL-1.1 OFL public-domain PSF-2 UoI-NCSA ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="bindist mirror splitdebug"
+
+BDEPEND="dev-util/patchelf"
+
+# RDEPENDS may cause false positives in repoman.
+# clion requires cmake and gdb at runtime to build and debug C/C++ projects
+RDEPEND="
+	app-accessibility/at-spi2-atk
+	app-accessibility/at-spi2-core
+	dev-libs/atk
+	dev-libs/libdbusmenu
+	dev-libs/nss
+	dev-util/cmake
+	media-libs/alsa-lib
+	media-libs/freetype
+	media-libs/mesa
+	net-print/cups
+	sys-devel/gdb
+	x11-libs/libdrm
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXi
+	x11-libs/libXScrnSaver
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	x11-libs/libXxf86vm
+	x11-libs/pango"
+
+QA_PREBUILT="opt/${P}/*"
+
+src_prepare() {
+	default
+
+	local remove_me=(
+		bin/gdb/linux
+		bin/lldb/linux
+		bin/cmake
+		license/CMake*
+		lib/pty4j-native/linux/aarch64
+		lib/pty4j-native/linux/mips64el
+		lib/pty4j-native/linux/ppc64le
+	)
+
+	use amd64 || remove_me+=( bin/fsnotifier64 lib/pty4j-native/linux/x86_64)
+	use x86 || remove_me+=( bin/fsnotifier lib/pty4j-native/linux/x86)
+
+	rm -rv "${remove_me[@]}" || die
+
+	for file in "jbr/lib/"/{libjcef.so,jcef_helper}
+	do
+		if [[ -f "${file}" ]]; then
+			patchelf --set-rpath '$ORIGIN' ${file} || die
+		fi
+	done
+}
+
+src_install() {
+	local dir="/opt/${P}"
+
+	insinto "${dir}"
+	doins -r *
+	fperms 755 "${dir}"/bin/{clion.sh,clang/linux/clang{d,-tidy}}
+
+	if use amd64; then
+		fperms 755 "${dir}"/bin/fsnotifier64
+	fi
+	if use arm; then
+		fperms 755 "${dir}"/bin/fsnotifier-arm
+	fi
+	if use x86; then
+		fperms 755 "${dir}"/bin/fsnotifier
+	fi
+
+	if [[ -d jbr ]]; then
+		fperms 755 "${dir}"/jbr/bin/{jaotc,java,javac,jdb,jjs,jrunscript,keytool,pack200,rmid,rmiregistry,serialver,unpack200}
+		# Fix #763582
+		fperms 755 "${dir}"/jbr/lib/{chrome-sandbox,jcef_helper,jexec,jspawnhelper}
+	fi
+
+	make_wrapper "${PN}" "${dir}/bin/${PN}.sh"
+	newicon "bin/${PN}.svg" "${PN}.svg"
+	make_desktop_entry "${PN}" "clion" "${PN}" "Development;IDE;"
+
+	# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
+	dodir /usr/lib/sysctl.d/
+	echo "fs.inotify.max_user_watches = 524288" > "${D}/usr/lib/sysctl.d/30-clion-inotify-watches.conf" || die
+}