dev-libs/libindicator: update EAPI 5 -> 7 in :3

Signed-off-by: Sam James <[email protected]>

dev-libs/libindicator/libindicator-12.10.1-r301.ebuild

@@ -1,8 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit autotools eutils flag-o-matic ltprune virtualx multilib-minimal
+EAPI=7
+
+inherit autotools flag-o-matic virtualx multilib-minimal
 
 DESCRIPTION="A set of symbols and convience functions that all indicators would like to use"
 HOMEPAGE="https://launchpad.net/libindicator"
@@ -14,39 +15,49 @@ KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc64 x86"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
-RDEPEND=">=dev-libs/glib-2.22[${MULTILIB_USEDEP}]
-	>=x11-libs/gtk+-3.2:3[${MULTILIB_USEDEP}]"
-DEPEND="${RDEPEND}
+RDEPEND="
+	>=dev-libs/glib-2.22[${MULTILIB_USEDEP}]
+	>=x11-libs/gtk+-3.2:3[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
 	dev-util/glib-utils
 	virtual/pkgconfig
 	test? ( dev-util/dbus-test-runner )"
 
-src_prepare() {
+PATCHES=(
 	# https://bugs.launchpad.net/libindicator/+bug/1502925
-	epatch "${FILESDIR}"/${PN}-ldflags-spacing.patch
+	"${FILESDIR}"/${PN}-ldflags-spacing.patch
+)
+
+src_prepare() {
+	default
+
 	eautoreconf
 }
 
 multilib_src_configure() {
 	append-flags -Wno-error
 
-	myconf=(
+	local myconf=(
 		--disable-static
 		--with-gtk=3
 	)
-	local ECONF_SOURCE=${S}
-	econf "${myconf[@]}"
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
 }
 
 multilib_src_test() {
-	Xemake check #391179
+	# bug #391179
+	Xemake check
 }
 
 multilib_src_install() {
 	emake -j1 DESTDIR="${D}" install
 }
 
 multilib_src_install_all() {
-	einstalldocs
-	prune_libtool_files --all
+	default
+
+	find "${ED}" -name '*.la' -delete || die
 }