dev-php/maxmind-db-reader: Version bump for 1.10.1

Signed-off-by: Brian Evans <[email protected]>

dev-php/maxmind-db-reader/Manifest

@@ -1 +1,2 @@
+DIST MaxMind-DB-Reader-php-1.10.1.tar.gz 23083 BLAKE2B f6684b07a184c4db7feebd9bf6b9afdc34c3de3b62bed59b2d01e1751eb996442d769576fbaa48e2bfa0572e80b2e0491d16d1cd9d89d35ca329e6dc17f74765 SHA512 841a03cf043ee0557e2157daee50d7f73211f5e665436eca8be6067d5357205093e40bb0402248fd6881d0d330feac96b298ec18763b8cb7d6d6392d54c59265
 DIST MaxMind-DB-Reader-php-1.6.0.tar.gz 20898 BLAKE2B cf6922bbd5b2c76fcb9b7a97299f0a73232686bf8facce39355f8a4cc55e98a4d8e64a51eae8427b5f14d6905d4cd85956effa5299cc493bd63708cf52ab30d0 SHA512 e8c0ccf2cfcedf7527b4e3f858d2ed0e70add60692fff4a65f08e5cb885516b7c2a3ceaa3c21713369cd8ffca2b671d764063236de1d729cfc5173f7d5dd4607

dev-php/maxmind-db-reader/maxmind-db-reader-1.10.1.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+MY_PN="MaxMind-DB-Reader-php"
+MY_P="${MY_PN}-${PV}"
+S="${WORKDIR}/${MY_P}"
+PHP_EXT_S="${S}/ext"
+PHP_EXT_NAME="maxminddb"
+PHP_EXT_OPTIONAL_USE="extension"
+
+USE_PHP="php7-3 php7-4 php8-0"
+
+inherit php-ext-source-r3
+
+DESCRIPTION="PHP reader for the MaxMind database format"
+HOMEPAGE="https://github.com/maxmind/MaxMind-DB-Reader-php"
+SRC_URI="https://github.com/maxmind/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="extension test"
+RESTRICT="!test? ( test )"
+
+DEPEND="extension? ( dev-libs/libmaxminddb )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# We need to call eapply_user ourselves, because it may be skipped
+	# if either the "extension" USE flag is not set, or if the user's
+	# PHP_TARGETS is essentially empty. In the latter case, the eclass
+	# src_prepare does nothing. We only call the eclass phase conditionally
+	# because the correct version of e.g. "phpize" may not be there
+	# unless USE=extension is set.
+	if use extension ; then
+		php-ext-source-r3_src_prepare
+	else
+		default
+	fi
+}
+
+src_configure() {
+	# The eclass phase will try to run the ./configure script even if it
+	# doesn't exist (in contrast to the default src_configure), so we
+	# need to skip it if the eclass src_prepare (that creates said
+	# script) is not run.
+	use extension && php-ext-source-r3_src_configure
+}
+
+src_compile() {
+	# Avoids the same problem as in src_configure.
+	use extension && php-ext-source-r3_src_compile
+}
+
+src_install() {
+	dodoc CHANGELOG.md README.md
+	insinto /usr/share/php
+	doins -r src/MaxMind
+	insinto /usr/share/php/MaxMind/Db
+	doins autoload.php
+
+	use extension && php-ext-source-r3_src_install
+}
+
+src_test() {
+	# The PHP API has its own set of tests that isn't shipped with the
+	# release tarballs at the moment (github issues 55).
+	use extension && php-ext-source-r3_src_test
+}
+
+pkg_postinst() {
+	elog "${PN} has been installed in /usr/share/php/MaxMind/Db/."
+	elog "To use it in a script, require('MaxMind/Db/autoload.php'),"
+	elog "and then most of the examples in the documentation should"
+	elog "work without further modification."
+}