gui-apps/waybar: add 0.9.24

Signed-off-by: Takuya Wakazono <[email protected]>
Signed-off-by: Yixun Lan <[email protected]>

gui-apps/waybar/Manifest

@@ -1,2 +1,3 @@
 DIST waybar-0.9.19.tar.gz 249917 BLAKE2B f2c5427544e8fe5d76302e34d3d02d214aa447865e1c33c86b21b9f025c8744ae6b95b5456a97f39dfbd12ab4408f9995f823718e0b2a486633f90303af0efa4 SHA512 32120bcf39b3b16d44a42e9121645e6d28c34b73dc54d30f4dcb40cb600865e3948fc839fde2f30c956e58627f7bef7f5e93a537223ca03350a016c77dde70c7
 DIST waybar-0.9.22.tar.gz 255896 BLAKE2B 51ad09f401a871f4b17552c85b838be950d52ebab6b2230619cfa95acbbc2f6cbc5ae1cb1228ca4207052397090f9fd4470388808cc81954b59c16f5cc25ed9e SHA512 0cd2d4fdf51528d1246da756ec1d4be5dd897208f4ec1aef5ab2d2801ab72145bcccef68fa62e55f0b1bb9913d471ce5c748de97f9d785d55c06a5f6717c9849
+DIST waybar-0.9.24.tar.gz 275416 BLAKE2B 15774a78f2f7bb85d497e7f80a968b775bb42d285d0950e8e384962c6b947ea895eea2b30c0aba7ca671595ce59acd65e66cf8b67f2478ecad7564de50e4bfe6 SHA512 13177fbc2c537cd903294ab708ae46307a785c524cbdbca06abe869af1f7ccc866ce38b6fbc2b3769cd95f458c46296b4c88ee927cabe890692e78b999143f0e

gui-apps/waybar/waybar-0.9.24.ebuild

@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors"
+HOMEPAGE="https://github.com/Alexays/Waybar"
+
+if [[ ${PV} == 9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/Alexays/${PN^}.git"
+else
+ SRC_URI="https://github.com/Alexays/${PN^}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64"
+ S="${WORKDIR}/${PN^}-${PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="evdev experimental jack +libinput +logind mpd mpris network +popups pipewire pulseaudio sndio systemd test tray +udev upower wifi"
+REQUIRED_USE="
+ mpris? ( logind )
+ upower? ( logind )
+"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+ >=app-text/scdoc-1.9.2
+ dev-util/gdbus-codegen
+ virtual/pkgconfig
+"
+RDEPEND="
+ dev-cpp/cairomm:0
+ dev-cpp/glibmm:2
+ dev-cpp/gtkmm:3.0
+ dev-libs/glib:2
+ dev-libs/jsoncpp:=
+ dev-libs/libinput:=
+ dev-libs/libsigc++:2
+ >=dev-libs/libfmt-8.1.1:=
+ >=dev-libs/spdlog-1.10.0:=
+ dev-libs/date:=
+ dev-libs/wayland
+ gui-libs/wlroots:=
+ x11-libs/gtk+:3[wayland]
+ x11-libs/libxkbcommon
+ evdev? ( dev-libs/libevdev:= )
+ jack? ( virtual/jack )
+ libinput? ( dev-libs/libinput:= )
+ logind? (
+ || ( sys-apps/systemd
+ sys-auth/elogind )
+ )
+ mpd? ( media-libs/libmpdclient )
+ mpris? ( >=media-sound/playerctl-2 )
+ network? ( dev-libs/libnl:3 )
+ popups? ( gui-libs/gtk-layer-shell )
+ pipewire? ( media-video/wireplumber:0/0.4 )
+ pulseaudio? ( media-libs/libpulse )
+ sndio? ( media-sound/sndio:= )
+ systemd? ( sys-apps/systemd:= )
+ tray? (
+ dev-libs/libdbusmenu[gtk3]
+ dev-libs/libayatana-appindicator
+ )
+ udev? ( virtual/libudev:= )
+ upower? ( sys-power/upower )
+ wifi? ( sys-apps/util-linux )
+"
+DEPEND="${RDEPEND}
+ dev-libs/wayland-protocols
+ test? ( dev-cpp/catch:0 )
+"
+
+src_configure() {
+ local emesonargs=(
+ -Dman-pages=enabled
+ -Dcava=disabled
+ $(meson_feature evdev libevdev)
+ $(meson_feature jack)
+ $(meson_feature libinput)
+ $(meson_feature logind)
+ $(meson_feature mpd)
+ $(meson_feature mpris)
+ $(meson_feature network libnl)
+ $(meson_feature popups gtk-layer-shell)
+ $(meson_feature pulseaudio)
+ $(meson_feature pipewire wireplumber)
+ $(meson_feature sndio)
+ $(meson_feature systemd)
+ $(meson_feature test tests)
+ $(meson_feature tray dbusmenu-gtk)
+ $(meson_feature udev libudev)
+ $(meson_feature upower upower_glib)
+ $(meson_feature wifi rfkill)
+ $(meson_use experimental)
+ )
+ meson_src_configure
+}