forked from gentoo/gentoo
-
Notifications
You must be signed in to change notification settings - Fork 0
Commit
This commit does not belong to any branch on this repository, and may belong to a fork outside of the repository.
Signed-off-by: Ionen Wolkens <[email protected]>
- Loading branch information
Showing
2 changed files
with
57 additions
and
0 deletions.
There are no files selected for viewing
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -1 +1,2 @@ | ||
DIST fceux-2.6.1.tar.gz 23326768 BLAKE2B 8a0907871af229cb8017845b444a8cc4ebe65dff0799483de488e984741fc89a885a9ecd421fef3a25175cc8f0855da68001fb6ea24f8e6955b2e1a02dc3f7d2 SHA512 f086003f676054a5527e3c1b81f9abdb76669e2b3935e7625f99d99ad0b122391646e8a186ca6a2840d5f03fff908630c11481b5166325ca91c08c2e46836f8d | ||
DIST fceux-2.6.2.tar.gz 23334976 BLAKE2B 70d05f6eb9befee1ee27f897c2da1494576fa2fc2b5057aff08ce8a227d0381063ed0ec65412c554b1520bc19c16e1f679b153ce8242842c0e0aad9ad9f315cf SHA512 11b8bc907997e0dee038f3956848653feb07f465204159e78a567362df6b250b14ddd6c2dcd5806f79d5032e27ff2b9dbf5dc59879616df89713381756f82848 |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -0,0 +1,56 @@ | ||
# Copyright 1999-2022 Gentoo Authors | ||
# Distributed under the terms of the GNU General Public License v2 | ||
|
||
EAPI=8 | ||
|
||
LUA_COMPAT=( lua5-1 ) | ||
inherit cmake lua-single xdg | ||
|
||
DESCRIPTION="Portable Famicom/NES emulator, an evolution of the original FCE Ultra" | ||
HOMEPAGE="https://fceux.com/" | ||
SRC_URI="mirror://sourceforge/fceultra/${P}.tar.gz" | ||
|
||
LICENSE="GPL-2+" | ||
SLOT="0" | ||
KEYWORDS="~amd64 ~x86" | ||
IUSE="ffmpeg x264 x265" | ||
REQUIRED_USE="${LUA_REQUIRED_USE}" | ||
|
||
# TODO: QT6 support (disabled by default) when available in Gentoo | ||
RDEPEND=" | ||
${LUA_DEPS} | ||
dev-qt/qtcore:5 | ||
dev-qt/qtgui:5 | ||
dev-qt/qtopengl:5[-gles2-only] | ||
dev-qt/qtwidgets:5 | ||
media-libs/libglvnd | ||
media-libs/libsdl2[joystick,sound,threads,video] | ||
sys-libs/zlib:=[minizip] | ||
ffmpeg? ( media-video/ffmpeg:= ) | ||
x264? ( media-libs/x264:= ) | ||
x265? ( media-libs/x265:= )" | ||
DEPEND="${RDEPEND}" | ||
|
||
PATCHES=( | ||
"${FILESDIR}"/${PN}-2.2.2-warnings.patch | ||
"${FILESDIR}"/${PN}-2.4.0-desktop.patch | ||
"${FILESDIR}"/${PN}-2.4.0-no-git.patch | ||
) | ||
|
||
src_prepare() { | ||
cmake_src_prepare | ||
|
||
use x264 || sed -i '/pkg_check_modules.*X264/d' src/CMakeLists.txt || die | ||
use x265 || sed -i '/pkg_check_modules.*X265/d' src/CMakeLists.txt || die | ||
use ffmpeg || sed -i '/pkg_check_modules.*LIBAV/d' src/CMakeLists.txt || die | ||
} | ||
|
||
src_install() { | ||
local DOCS=( README TODO-SDL changelog.txt documentation/. readme.md ) | ||
cmake_src_install | ||
|
||
# remove unused/duplicate files | ||
rm "${ED}"/usr/share/fceux/{lua5{1,.1}.dll,{fceux,taseditor}.chm} \ | ||
"${ED}"/usr/share/doc/${PF}/fceux{,-net-server}.6 \ | ||
"${ED}"/usr/share/man/man6/fceux-net-server.6 || die | ||
} |