gui-libs/wlroots: bump to 0.10.1

Closes: https://bugs.gentoo.org/716622
Signed-off-by: Aaron Bauman <[email protected]>

gui-libs/wlroots/Manifest

@@ -1 +1,2 @@
 DIST wlroots-0.10.0.tar.gz 454540 BLAKE2B 0d2326a62267019001be5f0d79c7b5c937ed20b952c92f0dd8cb04c3a0c06f3ef58723f552b1da1b947ea50ad91df46a543ec9705dad588db800bfa944743d11 SHA512 0e8e0c37f1afb1d99f0ecb3c2282992ffd06381aaa396c7234ead9f3ff2d5c599e766b677680ebaecf68e792054c3e42657d24f32d08bc8bcf35f9eb4bdaa876
+DIST wlroots-0.10.1.tar.gz 455232 BLAKE2B 0f4def61d8501b7746ccc589d59586b3641340fb7633b0c4a7b518f1b1b5285c1ee71fb629aa0a0e649c15a4ae69b5cfbc7a034c96e545765a96ddda35f10609 SHA512 e1af5a5b6484b5f4060090e13d22d699d5aaa6926e1a6b1043d2b900f88a002ed67dacf8498f23ed3008bf8a35500f415f95b3dbcf50de5da354f309f9161d58

gui-libs/wlroots/wlroots-0.10.1.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps meson
+
+DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
+HOMEPAGE="https://github.com/swaywm/wlroots"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/10"
+IUSE="elogind icccm systemd x11-backend X"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	>=dev-libs/libinput-1.9.0:0=
+	>=dev-libs/wayland-1.17.0
+	media-libs/mesa[egl,gles2,gbm]
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	elogind? ( >=sys-auth/elogind-237 )
+	icccm? ( x11-libs/xcb-util-wm )
+	systemd? ( >=sys-apps/systemd-237 )
+	x11-backend? ( x11-libs/libxcb:0= )
+	X? (
+		x11-base/xorg-server[wayland]
+		x11-libs/libxcb:0=
+		x11-libs/xcb-util-image
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.17
+	virtual/pkgconfig
+"
+
+# Patch is in upstream master. Probably drop on 0.10.2 or 0.11.
+PATCHES=("${FILESDIR}"/${PN}-gcc-10.patch)
+
+src_configure() {
+	# xcb-util-errors is not on Gentoo Repository (and upstream seems inactive?)
+	local emesonargs=(
+		"-Dxcb-errors=disabled"
+		-Dlibcap=$(usex filecaps enabled disabled)
+		-Dxcb-icccm=$(usex icccm enabled disabled)
+		-Dxwayland=$(usex X enabled disabled)
+		-Dx11-backend=$(usex x11-backend enabled disabled)
+		"-Dexamples=false"
+		"-Dwerror=false"
+	)
+	if use systemd; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd")
+	elif use elogind; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind")
+	else
+		emesonargs+=("-Dlogind=disabled")
+	fi
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	elog "You must be in the input group to allow your compositor"
+	elog "to access input devices via libinput."
+}