gui-apps/swayidle: 1.3 bump

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthew Thode <[email protected]>

gui-apps/swayidle/Manifest

@@ -1 +1,2 @@
 DIST swayidle-1.2.tar.gz 9136 BLAKE2B e88eec89007deed59df30f3f89111352b8a1ed464141783cb25b0d0a484e8ea4cfd611f1bd80d9420368d7912979eb0536a6aa583d24504d32bac797a898dba5 SHA512 2539e80a45163bb3e76f7b41f6fd6a1d73d194b7e466f63178b5087d05470fceafba38a26d592a534a01b992a2c0cf0f8fb83805cdf41ee956fea5136cc8fe89
+DIST swayidle-1.3.tar.gz 9714 BLAKE2B 2f57576be0fc9343c2dcacb0acbb06f105143e98e26650de71c9031ecf6702f98bb4f54a3d32a46f0d425a398ece511d35ad696e59f9e9b4ec6b8046a76da49b SHA512 efdf391870cd6eb2b21ef6556d8cfdec3c76c059c1f1065a55719bef55d3aef2a7fb39f38f0ac3a8e2e8a1ffa9df38635d7dc3397add7adf255db69c55b4351b

gui-apps/swayidle/swayidle-1.3.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Idle management daemon for Wayland"
+HOMEPAGE="https://github.com/swaywm/swayidle"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind fish-completion +man systemd zsh-completion"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	dev-libs/wayland
+	elogind? ( >=sys-auth/elogind-237[policykit] )
+	systemd? ( >=sys-apps/systemd-237[policykit] )
+"
+RDEPEND="
+	${DEPEND}
+	!<=gui-wm/sway-1.0_beta1
+	!~gui-wm/sway-1.0_beta2[swayidle]
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		$(meson_use fish-completion fish-completions)
+		$(meson_use zsh-completion zsh-completions)
+		"-Dbash-completions=true"
+		"-Dwerror=false"
+	)
+	if use systemd; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd")
+	elif use elogind; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind")
+	else
+		emesonargs+=("-Dlogind=disabled")
+	fi
+
+	meson_src_configure
+}

gui-apps/swayidle/swayidle-9999.ebuild

@@ -13,7 +13,7 @@ if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
 else
 	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
+	KEYWORDS="~amd64 ~arm64 ~x86"
 fi
 
 LICENSE="MIT"