app-cdr/cdrdao: fix use of uninit. var

Closes: https://bugs.gentoo.org/915133
Signed-off-by: Sam James <[email protected]>

app-cdr/cdrdao/cdrdao-1.2.5-r1.ebuild

@@ -0,0 +1,55 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic
+
+MY_PV="rel_${PV//./_}"
+DESCRIPTION="Burn CDs in disk-at-once mode with a command line interface"
+HOMEPAGE="https://github.com/cdrdao/cdrdao/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="encode mad vorbis"
+
+DEPEND="app-cdr/cdrtools
+	encode? ( >=media-sound/lame-3.99 )
+	mad? (
+		media-libs/libao
+		media-libs/libmad
+	)
+	vorbis? (
+		media-libs/libao
+		media-libs/libvorbis
+	)"
+RDEPEND="${DEPEND}
+	!app-cdr/cue2toc"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-remove-gconf-dep.patch"
+	"${FILESDIR}/${PN}-1.2.5-fix-uninit.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	append-cxxflags -std=c++11
+
+	filter-lto # https://bugs.gentoo.org/854219
+
+	local myeconfargs=(
+		--without-gcdmaster
+		$(use_with vorbis ogg-support)
+		$(use_with mad mp3-support)
+		$(use_with encode lame)
+	)
+	econf "${myeconfargs[@]}"
+}

app-cdr/cdrdao/files/cdrdao-1.2.5-fix-uninit.patch

@@ -0,0 +1,27 @@
+https://bugs.gentoo.org/915133
+https://github.com/cdrdao/cdrdao/issues/22
+https://github.com/cdrdao/cdrdao/pull/21
+
+From 251a40ab42305c412674c7c2d391374d91e91c95 Mon Sep 17 00:00:00 2001
+From: Ole Bertram <[email protected]>
+Date: Thu, 23 Mar 2023 17:08:48 +0100
+Subject: [PATCH] Fix uninitialized TOC data file name
+
+This caused spurious garbled TOC files and/or segfaults when not using
+the `--datafile` option.
+---
+ dao/main.cc | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/dao/main.cc b/dao/main.cc
+index 8bf4590..d09fc69 100644
+--- a/dao/main.cc
++++ b/dao/main.cc
+@@ -219,6 +219,7 @@ DaoCommandLine::DaoCommandLine() :
+     fullBurn(false), withCddb(false), taoSource(false), keepImage(false), overburn(false),
+     writeSpeedControl(false), keep(false), printQuery(false), no_utf8(false)
+ {
++    dataFilename = NULL;
+     readingSpeed = -1;
+     writingSpeed = -1;
+     command = UNKNOWN;