www-client/opera-developer: Version 62.0.3331.2

Package-Manager: Portage-2.3.67, Repoman-2.3.13
Signed-off-by: Jeroen Roovers <[email protected]>

www-client/opera-developer/Manifest

@@ -1,2 +1,3 @@
 DIST opera-developer_62.0.3319.0_amd64.deb 66755102 BLAKE2B b51574dee9b05bdd687aeab5a7a3685013ef7f5119da753b982e383cc7d3e86b2b23fae6d201031858afd2893e5bd5f0f3c6b7ad5e4801ecbcca67213e0c7515 SHA512 14c6cd45dcaae839022e0da347faaacf0602a0444e3849503b017fe63b7f31e029dacb7d1418feede59601d173f97054979874bda144e69d119151b9f78c2158
 DIST opera-developer_62.0.3323.0_amd64.deb 66692130 BLAKE2B 72a00ef3eb167a257aedf8e0cdd7928f6306e57d81507a1ff864608d863370e172264b2ac54d68a6d86f1cf900179d10a2f8fb40446388585e5240d58041ddb0 SHA512 a9bc7d93117853c82a85839504da0a1ab59950a745e2193477885144cee460b98501b88576eecd7360ad17c6e10282345230c31ef2a5c203e53b2c5cef65ee06
+DIST opera-developer_62.0.3331.2_amd64.deb 65860794 BLAKE2B 2ea22afe0057f3c15cb54d6aab858f3b2beb63fb127d3b46ab2dfa6cb1b83710ab8f8a4503bf06996a12e51dce2f5997ae996e76026f767f67df3d80e67aa5f6 SHA512 1e652fbc35b72b5f655bb8d235c49c721a958a43db04124c2285bbc5499d0e301453be2b071a85cdc98f672fc0ada0e3e5513ac96c726453cb2afb925d442a12

www-client/opera-developer/opera-developer-62.0.3331.2.ebuild

@@ -0,0 +1,115 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+pkg_setup() {
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_prepare() {
+	default
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	rm usr/bin/${PN} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}