net-irc/irssi: security bump per upstream notification

Package-Manager: portage-2.3.2

net-irc/irssi/Manifest

@@ -1 +1,2 @@
 DIST irssi-0.8.20.tar.xz 1007252 SHA256 7882c4e821f5aac469c5e69e69d7e235f4986101285c675e81a9a95bfb20505a SHA512 ace39022a3e7461fc33cbd0e8c6635aa84c67fc4f6364b66747f860a4538a4b17bbd677e342fbfa9ae7e97783745f8d7dab350a27330ce14f1702386231296b1 WHIRLPOOL 3a50767aebed4dbd7fea7639af688cbc6cd2b57a7bae9ab398d277471dbea3491d918c46cf0c05ff48db69b79117c0d733dfe06c2bc0b9bbfce699eb0fdcff37
+DIST irssi-0.8.21.tar.xz 1007524 SHA256 e433063b8714dcf17438126902c9a9d5c97944b3185ecd0fc5ae25c4959bf35a SHA512 110934ab85c8574fc76bce367c58378e28603898e63a5014a72170ffe441ffe3dbda432531e899176f5c4126f47d929a3a01a2f87bcacbfe0ba4d6d8cb31e642 WHIRLPOOL 8426a82cbf5b488c1fd9497fdeb69ee98d211aa9775560b9d6efc9645d74926fff6b627c2f681642a0df10e83f68dc4d6403d706faaf677391005af5bdccf143

net-irc/irssi/irssi-0.8.21.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic perl-module toolchain-funcs
+
+# Keep for _rc compability
+MY_P="${P/_/-}"
+
+DESCRIPTION="A modular textUI IRC client with IPv6 support"
+HOMEPAGE="http://irssi.org/"
+SRC_URI="https://github.com/irssi/irssi/releases/download/${PV/_/-}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="ipv6 +perl selinux ssl socks5 +proxy libressl"
+
+CDEPEND="sys-libs/ncurses:0=
+	>=dev-libs/glib-2.6.0
+	ssl? (
+		!libressl? ( dev-libs/openssl:= )
+		libressl? ( dev-libs/libressl:= )
+	)
+	perl? ( dev-lang/perl:= )
+	socks5? ( >=net-proxy/dante-1.1.18 )"
+
+DEPEND="
+	${CDEPEND}
+	virtual/pkgconfig"
+
+RDEPEND="
+	${CDEPEND}
+	selinux? ( sec-policy/selinux-irc )
+	perl? ( !net-im/silc-client )"
+
+RESTRICT="test"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.8.20-tinfo.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-ncurses="${EPREFIX}"/usr \
+		--with-perl-lib=vendor \
+		--enable-static \
+		--enable-true-color \
+		$(use_with proxy) \
+		$(use_with perl) \
+		$(use_with socks5 socks) \
+		$(use_enable ssl) \
+		$(use_enable ipv6)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	use perl && perl_delete_localpod
+
+	prune_libtool_files --modules
+
+	dodoc AUTHORS ChangeLog README.md TODO NEWS
+}