sci-chemistry/avogadro2: add 1.97.0

Bug: https://bugs.gentoo.org/868132
Signed-off-by: Andrew Ammerlaan <[email protected]>

sci-chemistry/avogadro2/Manifest

@@ -1,2 +1,4 @@
 DIST avogadro2-1.95.1-i18n.tar.gz 800520 BLAKE2B f68edce572335621deb9698d1cc97d4d8e900ea91bb7a428a4da63d9060c38b31181b91b868378ab5da29c7a61ccb0f6efd9b422bba2d9dc9bb86578c23152c4 SHA512 1182578a9b91f49d114fa3a201e5fe5c37d3abdd10dff82be04f6d5fd193dd3b1140e7abdf2cf721523f523d762fbdc97780887184b83edbc9d3fa87fd8f7428
 DIST avogadro2-1.95.1.tar.gz 2888376 BLAKE2B 00ad2b9daccec77207d42bd0db0cf404bd5b92941385f19ac35400cf497884d198785da60f87fd68e92f6d864abea31f07526c2053b34cbf75d1202fd9232694 SHA512 15300da0ecc85be0e369758aafa50ca5c236132988da68611f198637ea49f4a88da93d58ecd177aeb3c2ac363c0da79b91064156e61c828a059277aa09245604
+DIST avogadro2-1.97.0-i18n.tar.gz 990218 BLAKE2B e76b2d69b74f2a2964383564018e61ff0248e53c62a4a2abb1033100bd7fadaefbc261e64bf9e809d6e12ef851bd1ca3661d78b70d07728476586f6564e44e63 SHA512 6a01a05d4a62f83a75ae13100229f2ac6f9e697412868a75f5a9fde6025fc4e886c7ac80704fe5b8390a2af437c7848b0dce19897a6f9da1c5cf4c83418523db
+DIST avogadro2-1.97.0.tar.gz 2931223 BLAKE2B b2f2146ebe94ef25f4f684b13f9b9c5fbba933978208524ee197c8971f96c733f687ec68e566d032381a5f45cf22defb2bf909bd738becdd70da0abccebc0755 SHA512 19a0bcf01a840da29c4bab6eed55c879c10d773ee5dcfab613e6666708916bfd8398e44237c18de4e5bb3247d3c4bed3844cac47cf7f3a94dc96d7df8eb13579

sci-chemistry/avogadro2/avogadro2-1.97.0.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+MY_PN=avogadroapp
+
+DOCS_BUILDER="doxygen"
+DOCS_DEPEND="media-gfx/graphviz"
+DOCS_DIR="${WORKDIR}/${MY_PN}-${PV}_build/docs"
+# docs/CMakeLists.txt overwrites docs.eclass outdir if we do not set this
+DOCS_OUTDIR="${DOCS_DIR}/html"
+DOCS_CONFIG_NAME="doxyfile"
+inherit desktop docs cmake xdg
+
+I18N_COMMIT="13c4286102373658cea48a33b86536ab5793da66"
+
+DESCRIPTION="Advanced molecule editor and visualizer 2"
+HOMEPAGE="https://www.openchemistry.org/"
+SRC_URI="
+	https://github.com/OpenChemistry/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/OpenChemistry/avogadro-i18n/archive/${I18N_COMMIT}.tar.gz -> ${P}-i18n.tar.gz
+"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+SLOT="0"
+LICENSE="BSD GPL-2+"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="rpc test vtk"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	>=sci-libs/avogadrolibs-${PV}[qt5,vtk?]
+	sci-libs/hdf5:=
+	rpc? ( sci-chemistry/molequeue )
+"
+DEPEND="${RDEPEND}
+	dev-cpp/eigen:3
+	test? ( dev-qt/qttest:5 )
+"
+
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.95.1-qttest.patch"
+)
+
+src_unpack() {
+	default
+	mv "${WORKDIR}/avogadro-i18n-${I18N_COMMIT}" "${WORKDIR}/avogadro-i18n" || die
+}
+
+src_prepare() {
+	cmake_src_prepare
+	sed -e "/LICENSE/d" -i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_DOC_DIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DAvogadro_ENABLE_RPC=$(usex rpc)
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_VTK=$(usex vtk)
+	)
+	# Need this to prevent overwriting the documentation OUTDIR
+	use doc && mycmakeargs+=( -DChemData_BINARY_DIR="${DOCS_OUTDIR}" )
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	docs_compile
+}
+
+src_install() {
+	cmake_src_install
+	for size in 64 128 256 512; do
+		newicon -s "${size}" avogadro/icons/"${PN}"_"${size}".png "${PN}".png
+	done
+}