kde-apps/kmix: 21.12.0 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

kde-apps/kmix/Manifest

@@ -1 +1,2 @@
 DIST kmix-21.08.3.tar.xz 1163772 BLAKE2B 4855c3837694ddff6cf74eaf2d598659c4267902acebe445c5902b233dc3de5fd8287e77441079a9bc8e3bcc1a6ba065ec9b2a5c7543d00985ba62b2cafe75d9 SHA512 833026a027b4f131aa73969c6c86c79fb61a382707e1f53865c623d77a2a7eb8199cbd4e3a178574fd40a5c9f1ede179da5bce1a82bcfd7685c8278847f3fe48
+DIST kmix-21.12.0.tar.xz 1164124 BLAKE2B 9df105032b1c1c003d333c5a43436976b79012626f6d81d468cda499d9979740783737c84617ae9a9d2186ce952ab3378d6200db52a806735aff1fd8846f21ad SHA512 57d46fbe6f26b46e9d01e1c5a474b4fc2e780404f2484764bca67558a75616d4682f1cda75abeeb937b10230afc70158196bf83784436e170f4724e05540d645

kde-apps/kmix/kmix-21.12.0.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="false"
+KFMIN=5.88.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Volume control gui based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kmix/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa plasma pulseaudio"
+
+DEPEND="
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=dev-qt/qtxml-${QTMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kdbusaddons-${KFMIN}:5
+ >=kde-frameworks/kglobalaccel-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/knotifications-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+ >=kde-frameworks/kwindowsystem-${KFMIN}:5
+ >=kde-frameworks/kxmlgui-${KFMIN}:5
+ >=kde-frameworks/solid-${KFMIN}:5
+ alsa? ( >=media-libs/alsa-lib-1.0.14a )
+ plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
+ pulseaudio? (
+ media-libs/libcanberra
+ >=media-sound/pulseaudio-0.9.12
+ )
+"
+RDEPEND="${DEPEND}
+ kde-plasma/kde-cli-tools:5
+ pulseaudio? ( || (
+ media-video/pipewire
+ media-sound/pulseaudio-daemon
+ media-sound/pulseaudio[daemon(+)]
+ ) )
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package alsa ALSA)
+ -DBUILD_DATAENGINE=$(usex plasma)
+ $(cmake_use_find_package pulseaudio Canberra)
+ $(cmake_use_find_package pulseaudio PulseAudio)
+ )
+
+ ecm_src_configure
+}
+
+pkg_postinst() {
+ if use pulseaudio && has_version kde-plasma/plasma-pa; then
+ elog "In KDE Plasma, kde-plasma/plasma-pa is the default audio volume handler."
+ elog "Should you prefer this to be kde-apps/kmix instead, do the following:"
+ elog " - In system tray, right click on [Show hidden items]"
+ elog " - Select [Configure System Tray]"
+ elog " - In [Entries], search for [Audio Volume] and set it to [Disabled]"
+ elog "KMix will be shown as [Volume Control]."
+ fi
+ ecm_pkg_postinst
+}