Skip to content

Commit

Permalink
kde-plasma/plasma-desktop: 5.20.0 version bump
Browse files Browse the repository at this point in the history 
Add IUSE="kaccounts" description

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Andreas Sturmlechner <[email protected]>
  • Loading branch information
@a17r
a17r committed Oct 13, 2020
1 parent a1d4f66 commit af6e342
Show file tree
Hide file tree
Showing 3 changed files with 162 additions and 0 deletions.
1 change: 1 addition & 0 deletions kde-plasma/plasma-desktop/Manifest
View file
Original file line number Diff line number Diff line change
@@ -1,2 +1,3 @@
DIST plasma-desktop-5.19.5.tar.xz 9430088 BLAKE2B 02894dfdc8c0d4535782629059b7d69e7722c63ef47c44077d5b49ac489b53af8440ba361a31a327783fe7a2b56d1812d59c8f6f0797c8fcc81aa90c1fac96c4 SHA512 d7c7b26dc5a7d4804a780833f8d22797312b845962ed4f9218c448fcb3c720c032eca1e79bec5f9c084f1825f0b6f26c34ffe032320396c9092e04a5b05c3d12
DIST plasma-desktop-5.20.0.tar.xz 15860268 BLAKE2B 7c9e3d43251c5229fd46b618920dcbd449ba187637fe827e40a18a47481b12fc01617d8879fff18879fed497d143fbf0ed1129aac2b11949c34369988174339c SHA512 d34560977b75854a80cd75a9a15c9fed614ea9c36a724c2e5df9ae6e3439762a34d7afe33892beae2e7dff3fc555673f27069c43bb0bf774ad8740e3476be651
DIST plasma-desktop-override-include-dirs-0.tar.xz 7504 BLAKE2B 781a2f0f7ca5a45b966edfc79012e80c6826262a211d95b725590191a8828e0002fd924a49cc63c12090535077a24f3e719ca3277aac89aba3092e86f73d7f61 SHA512 d23dc203b8b645472c9c192a3d73ef9b46c66d9c64df1c90efa05c9968ec125e0a256bc9b654f05a1f22bce4b1d8aad436f581b42d579f4195a44f062fd444bb
1 change: 1 addition & 0 deletions kde-plasma/plasma-desktop/metadata.xml
View file
Original file line number Diff line number Diff line change
Expand Up @@ -8,6 +8,7 @@
<use>
<flag name="emoji">Build emojipicker applet using <pkg>app-i18n/ibus</pkg> and <pkg>media-fonts/noto-emoji</pkg></flag>
<flag name="ibus">Use ibus input method via <pkg>app-i18n/ibus</pkg></flag>
<flag name="kaccounts">Build the OpenDesktop integration plugin</flag>
<flag name="scim">Enable applets that use <pkg>app-i18n/scim</pkg></flag>
</use>
</pkgmetadata>
160 changes: 160 additions & 0 deletions kde-plasma/plasma-desktop/plasma-desktop-5.20.0.ebuild
View file
Original file line number Diff line number Diff line change
@@ -0,0 +1,160 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

ECM_HANDBOOK="forceoptional"
ECM_TEST="true"
KFMIN=5.74.0
PVCUT=$(ver_cut 1-3)
QTMIN=5.15.1
VIRTUALX_REQUIRED="test"
inherit ecm kde.org

DESCRIPTION="KDE Plasma desktop"
XORGHDRS="${PN}-override-include-dirs-0"
SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz"

LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
IUSE="emoji ibus +kaccounts scim +semantic-desktop"

BDEPEND="virtual/pkgconfig"
COMMON_DEPEND="
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtprintsupport-${QTMIN}:5
>=dev-qt/qtsql-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtx11extras-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=kde-frameworks/attica-${KFMIN}:5
>=kde-frameworks/kactivities-${KFMIN}:5
>=kde-frameworks/kactivities-stats-${KFMIN}:5
>=kde-frameworks/karchive-${KFMIN}:5
>=kde-frameworks/kauth-${KFMIN}:5
>=kde-frameworks/kbookmarks-${KFMIN}:5
>=kde-frameworks/kcmutils-${KFMIN}:5
>=kde-frameworks/kcodecs-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/kdeclarative-${KFMIN}:5
>=kde-frameworks/kded-${KFMIN}:5
>=kde-frameworks/kdelibs4support-${KFMIN}:5
>=kde-frameworks/kglobalaccel-${KFMIN}:5
>=kde-frameworks/kguiaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kitemmodels-${KFMIN}:5
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/krunner-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/plasma-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=kde-frameworks/sonnet-${KFMIN}:5
>=kde-plasma/kwin-${PVCUT}:5
>=kde-plasma/libksysguard-${PVCUT}:5
>=kde-plasma/plasma-workspace-${PVCUT}:5
>=media-libs/phonon-4.11.0
x11-libs/libX11
x11-libs/libXfixes
x11-libs/libXi
x11-libs/libxcb[xkb]
x11-libs/libxkbfile
emoji? (
app-i18n/ibus[emoji]
dev-libs/glib:2
media-fonts/noto-emoji
)
ibus? (
app-i18n/ibus
dev-libs/glib:2
>=dev-qt/qtx11extras-${QTMIN}:5
x11-libs/libxcb
x11-libs/xcb-util-keysyms
)
kaccounts? (
kde-apps/kaccounts-integration:5
net-libs/accounts-qt
)
scim? ( app-i18n/scim )
semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
"
DEPEND="${COMMON_DEPEND}
dev-libs/boost
x11-base/xorg-proto
"
RDEPEND="${COMMON_DEPEND}
!<kde-plasma/kdeplasma-addons-5.15.80
!kde-plasma/user-manager
>=dev-qt/qtgraphicaleffects-${QTMIN}:5
>=dev-qt/qtquickcontrols2-${QTMIN}:5
>=kde-frameworks/kirigami-${KFMIN}:5
>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
>=kde-plasma/breeze-${PVCUT}:5
>=kde-plasma/kde-cli-tools-${PVCUT}:5
>=kde-plasma/oxygen-${PVCUT}:5
sys-apps/util-linux
x11-apps/setxkbmap
kaccounts? ( net-libs/signon-oauth2 )
"

PATCHES=(
"${WORKDIR}/${XORGHDRS}/override-include-dirs.patch" # downstream patch
)

src_prepare() {
ecm_src_prepare

if ! use ibus; then
sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
fi
}

src_configure() {
local mycmakeargs=(
-DEvdev_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
-DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
-DSynaptics_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
$(cmake_use_find_package kaccounts AccountsQt5)
$(cmake_use_find_package kaccounts KAccounts)
$(cmake_use_find_package scim SCIM)
$(cmake_use_find_package semantic-desktop KF5Baloo)
)
if ! use emoji && ! use ibus; then
mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_IBus=ON )
fi

ecm_src_configure
}

src_test() {
# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
# test_kio_fonts needs D-Bus, bug #634166
# lookandfeel-kcmTest is unreliable for a long time, bug #607918
local myctestargs=(
-j1
-E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
)

ecm_src_test
}

0 comments on commit af6e342

Please sign in to comment.