Version bump to 2.4.1

Package-Manager: portage-2.2.27

app-portage/layman/Manifest

@@ -3,3 +3,4 @@ DIST layman-2.1.0.tar.gz 94150 SHA256 cb96306c84da1d49ff54a31f7511c62c859565361b
 DIST layman-2.2.0.tar.gz 116210 SHA256 4a10cfd3eb354e993886369995ae9b1243418e0370c6aabd4d0ef6c5b387b7a2 SHA512 34cac041d7b64274debdbc42cab079fd3bb3aee511ea9e80db726df0f828207d79a5262788483ced5cbf49924e3aa4f19fe21439c98dceea973d8f83473c2e41 WHIRLPOOL 8c5d3cbbfef35c6294dfac899cb42f49e0761745573721e38b7d6c9ac48031f95bbb961c9d8dd9d309e4672cc1e5b050107ba025a9f28127e5d7d6d9a73a6e9a
 DIST layman-2.3.0.tar.gz 119223 SHA256 76559b8e202c012d124deac01b92bbe70b550afe711144a3b1e301c5d8bbd0f2 SHA512 d110fb1781017d87e995098ecb48c4223347323d67534b584a393dc4354b761a6d960fd31e6e6787b5f37fa7e63b357c49486042c7cb527f78dd5beb5373627d WHIRLPOOL 76c82f08b18830e925ffd4c97b490753de2e7d0b3c71a82a0a75fd776ed3af84d2ba2fe06dab25e5e4d2ea400b0f0b66eda65f1f4eded0521ec579a1a0c1b17f
 DIST layman-2.4.0.tar.gz 130052 SHA256 0dd9dbcd05b5bf062139308cb812507b2c3310dd81f25c9cdc4c8f643b3f74c8 SHA512 011ac0e7dfed8415b875898ff1eecfe77ba5a68ccac208d8f5c693b9b880355ffef572490bb98ede62092bea1a84298bbd72e6c93a234fdfa319e96551e7eb07 WHIRLPOOL 0fdcd09ef4347f9450897237befd6fa73187a3e5ed0eff6b08345846ff270cd9751a3f38277f7b53baffb3b9a3e18e10f08ebe33c228ed7f7ccd01ce81d05a76
+DIST layman-2.4.1.tar.gz 130388 SHA256 545792a15a0a2514c79f1b3090aceef15e413c656f294b6ff84f8a36da7aa2da SHA512 bdb713d4c7d3773129b45a385068278958040759bb564e48cfda4dda9da5224ccaa7833fce3d06151ed1fecddbb6f1a059db6e71534d0e887dff12640af6c806 WHIRLPOOL b6ef18f8f3633e9bb2a08df620306441f8352174dc66f2bbb68613cff0796e0914f7008de4f185167815ba3267c3b63a4fe22d2bcd794f70cd78bc20e706d7d8

app-portage/layman/layman-2.4.1.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} pypy )
+PYTHON_REQ_USE="xml(+),sqlite?"
+
+inherit eutils distutils-r1 linux-info prefix
+
+DESCRIPTION="Tool to manage Gentoo overlays"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Layman"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~s390 ~x86"
+IUSE="bazaar cvs darcs +git gpg g-sorcery mercurial sqlite squashfs subversion sync-plugin-portage test"
+
+DEPEND="test? ( dev-vcs/subversion )
+	"
+
+RDEPEND="
+	bazaar? ( dev-vcs/bzr )
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	g-sorcery? ( app-portage/g-sorcery )
+	subversion? (
+		|| (
+			>=dev-vcs/subversion-1.5.4[http]
+			>=dev-vcs/subversion-1.5.4[webdav-neon]
+			>=dev-vcs/subversion-1.5.4[webdav-serf]
+		)
+	)
+	gpg? ( =dev-python/pyGPG-0.2 )
+	sync-plugin-portage?  ( >=sys-apps/portage-2.2.16[${PYTHON_USEDEP}] )
+	!sync-plugin-portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
+	>=dev-python/ssl-fetch-0.4[${PYTHON_USEDEP}]
+	"
+
+layman_check_kernel_config() {
+	local CONFIG_CHECK
+	use squashfs && CONFIG_CHECK+=" ~BLK_DEV_LOOP ~SQUASHFS"
+	[[ -n ${CONFIG_CHECK} ]] && check_extra_config
+}
+
+pkg_pretend() {
+	layman_check_kernel_config
+}
+
+pkg_setup() {
+	layman_check_kernel_config
+}
+
+python_prepare_all()  {
+	python_setup
+	esetup.py setup_plugins
+	distutils-r1_python_prepare_all
+	eprefixify etc/layman.cfg layman/config.py
+}
+
+python_test() {
+	suite=layman/tests/external.py
+	PYTHONPATH="." "${PYTHON}" ${suite} || die "test suite '${suite}' failed"
+	unset suite
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/layman
+	doins etc/layman.cfg
+
+	doman doc/layman.8
+	dohtml doc/layman.8.html
+
+	keepdir /var/lib/layman
+	keepdir /etc/layman/overlays
+}
+
+pkg_postinst() {
+	# now run layman's update utility
+	einfo "Running layman-updater..."
+	"${EROOT}"/usr/bin/layman-updater
+	einfo
+}