dev-python/aesara: Bump to 2.7.1

Signed-off-by: Michał Górny <[email protected]>

dev-python/aesara/Manifest

@@ -1,2 +1,3 @@
 DIST aesara-rel-2.6.6.tar.gz 7847814 BLAKE2B e4edd575d49f548fab0ef971dbab88beeb43859ec7b80612145ed490b31d6e7dc6b6818653396938124a22fa2f54f8d151c5039cc2e9c9070c88cce9cb1c5596 SHA512 028a208fc7e5921ce1df34dd23a42cf90d419e06f0192d9a006ebfb8c5f36e35e347214e53f53e688a1144063c7f4853a8cd44eef6fc205225147116839008de
 DIST aesara-rel-2.7.0.gh.tar.gz 7854953 BLAKE2B 0daee9dcad9c39d1eddd469930cb540369f9463f947d706691fe1552b8e39340743aa8d8a809fe8b7943bba253ef1b93018738ca13be7147114ab6cf77a3ee37 SHA512 b03a182f366624b496bee46b86d43c68b94d840503317af74113bd5b1c6fefc31e4e4d96d6c5dd129212904729127da949cebf05c5a162711d3872e1747c93a8
+DIST aesara-rel-2.7.1.gh.tar.gz 7857341 BLAKE2B edc31030810ec4193901d258c8666080219befccca17bc6165968f959bd57661f92de86720561ab54266906e2be1a83e0fef3e81a62c2810f0b78cda1dbc5265 SHA512 85a4b24a5f58cbb95db448d01140ff64f9ea39242b204a49ddbb2ff8827a16d0ba454764ed3ce9d2b6ed58a7494c452cda39582ae89691d44d8f91ec43e1f50d

dev-python/aesara/aesara-2.7.1.ebuild

@@ -0,0 +1,90 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 multiprocessing optfeature
+
+MY_P=aesara-rel-${PV}
+DESCRIPTION="Library for operating on mathematical expressions with multi-dimensional arrays"
+HOMEPAGE="
+ https://github.com/aesara-devs/aesara/
+ https://pypi.org/project/aesara/
+"
+SRC_URI="
+ https://github.com/aesara-devs/aesara/archive/rel-${PV}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+ dev-python/cons[${PYTHON_USEDEP}]
+ dev-python/etuples[${PYTHON_USEDEP}]
+ dev-python/logical-unification[${PYTHON_USEDEP}]
+ dev-python/minikanren[${PYTHON_USEDEP}]
+ dev-python/filelock[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ dev-python/scipy[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ )
+"
+
+PATCHES=(
+ "${FILESDIR}"/aesara-2.6.5-compiledir-tid.patch
+)
+
+distutils_enable_sphinx doc 'dev-python/sphinx_rtd_theme'
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # speed tests are unreliable
+ tests/scan/test_basic.py::test_speed
+ tests/scan/test_basic.py::test_speed_rnn
+ tests/scan/test_basic.py::test_speed_batchrnn
+ tests/link/test_vm.py::test_speed
+ tests/link/test_vm.py::test_speed_lazy
+ tests/tensor/test_gc.py::test_merge_opt_runtime
+
+ # rounding problem?
+ # https://github.com/aesara-devs/aesara/issues/477
+ tests/tensor/test_math_scipy.py::TestGammaUBroadcast::test_good
+ tests/tensor/test_math_scipy.py::TestGammaUInplaceBroadcast::test_good
+ )
+ local EPYTEST_IGNORE=(
+ # we do not package numba
+ tests/link/test_numba.py
+ tests/link/test_numba_performance.py
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x AESARA_FLAGS="cxx=${CXX}"
+ AESARA_FLAGS+=",config.gcc__cxxflags=\"${CXXFLAGS}\""
+ AESARA_FLAGS+=',compiledir_format="compiledir_%(thread_id)s"'
+
+ epytest -p xdist.plugin -n "$(makeopts_jobs)"
+ # clean up the compiledir, as it can grow pretty large
+ rm -r "${HOME}"/.aesara || die
+}
+
+python_compile() {
+ distutils-r1_python_compile
+ rm "${BUILD_DIR}/install$(python_get_sitedir)/bin/__init__.py" || die
+}
+
+pkg_postinst() {
+ optfeature "GPU code generation/execution on NVIDIA gpus" dev-util/nvidia-cuda-toolkit dev-util/nvidia-cuda-sdk
+ optfeature "GPU/CPU code generation on CUDA and OpenCL devices" dev-libs/libgpuarray dev-python/pycuda
+}