x11-libs/libva: Bump to version 2.5.0

Package-Manager: Portage-2.3.68, Repoman-2.3.16
Signed-off-by: Lars Wendler <[email protected]>

x11-libs/libva/Manifest

@@ -5,3 +5,4 @@ DIST libva-2.2.0.tar.gz 218971 BLAKE2B c715f5f94cf25bcdf03be9ddeeb390fc073fe3fc7
 DIST libva-2.3.0.tar.gz 222152 BLAKE2B 235cb4ba79eeac334163e32b51313f74506e54a7ca5693b81a2bf00eff1d5204ba630e32028dc02fb47268772d12032471d7d6d47e189318230e8a52cc940fcc SHA512 b328e7426bd5fb33a4ed4817d7a33fb104b1f524f5ca83f60349df66cff22e9cd46d40238d29d5bf527f32c7da153088525e43d50454832ac9b4b7fe0be40692
 DIST libva-2.4.0.tar.bz2 455989 BLAKE2B 740460b5e23fc09dbb4de61dbe6c7d3820032d54d0ff9895d0a5e3235362e559e50d5349eab4c907367cef101f367256a9da3cf3a87526c444450f830b0ac4d6 SHA512 67373e20932bca0d52cd8f48ed10c1f01752be73642ad4d2c85dcee813dccf205c8ca62fdc69fb3f4f83a685e2a8ef2c6646174e3453a8f5763cac16a58321c3
 DIST libva-2.4.1.tar.bz2 456435 BLAKE2B 8500d5d234f6b5841611b7e46c9a729d8becaba0ce8311fe41cc6689339fb80ae665a974152c04c9b7ae5ce7693ed2549c3c0f284d8b21ecb25964745b6f43e1 SHA512 24af06e407c833f588e05e2be853bf004b0322d35ab35838ec2705c4158feb41e8ecc3a1b619fc291dfa7da49c8e17dd49993937624df0d4ed7ee2dbb90b1568
+DIST libva-2.5.0.tar.bz2 459677 BLAKE2B d6e5bf94bcbda0a724634164bd8cf91efbdbe36120e62e7e7eefcd749afffec1950d8904318b472c81ae07490c559c68b0853725c654a08592457118cd5d6a83 SHA512 ffaeb9cf8ed1f93073c1cb3e58f5b3d3612e81622d02f8e428c089f625d4370b496b7681ac2fc2823c48670c9fd3da50893b1db51de768cf0f5d866e2ee78106

x11-libs/libva/libva-2.5.0.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+
+if [[ ${PV} = *9999* ]] ; then # Live ebuild
+	inherit autotools git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/libva"
+	AUTOTOOLS_AUTORECONF="yes"
+else
+	SRC_URI="https://github.com/intel/libva/releases/download/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="+drm opengl utils vdpau wayland X"
+
+VIDEO_CARDS="nvidia intel i965 nouveau"
+for x in ${VIDEO_CARDS}; do
+	IUSE+=" video_cards_${x}"
+done
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}]
+	opengl? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.11[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+PDEPEND="video_cards_nvidia? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB_USEDEP}] )
+	video_cards_nouveau? ( >=x11-libs/libva-vdpau-driver-0.7.4-r3[${MULTILIB_USEDEP}] )
+	vdpau? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB_USEDEP}] )
+	video_cards_intel? ( >=x11-libs/libva-intel-driver-2.0.0[${MULTILIB_USEDEP}] )
+	video_cards_i965? ( >=x11-libs/libva-intel-driver-2.0.0[${MULTILIB_USEDEP}] )
+	utils? ( media-video/libva-utils )
+"
+
+REQUIRED_USE="|| ( drm wayland X )
+	opengl? ( X )"
+
+DOCS=( NEWS )
+
+MULTILIB_WRAPPED_HEADERS=(
+/usr/include/va/va_backend_glx.h
+/usr/include/va/va_x11.h
+/usr/include/va/va_dri2.h
+/usr/include/va/va_dricommon.h
+/usr/include/va/va_glx.h
+)
+
+src_prepare() {
+	default
+	[[ "${PV}" == *9999* ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--with-drivers-path="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		$(use_enable opengl glx)
+		$(use_enable X x11)
+		$(use_enable wayland)
+		$(use_enable drm)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}