games-engines/scummvm: Bump to 2.6.0

Signed-off-by: Michał Górny <[email protected]>

games-engines/scummvm/Manifest

@@ -1,3 +1,4 @@
 DIST scummvm-2.2.0.tar.xz 63652348 BLAKE2B b44a07d7ad6747b136465f81122464f02e5cc655c205d6f4424555311563f8ceaa8072972d05512af85d18fabba78d5ea9396ea314581776c1ef8d88ca6ab81b SHA512 001f884b9689386ef5b69ab8f5fa2362e1e4dc5e8273f96dc8dce1963be354a2fad95e724ff33d65008be7591519f0e2bac530ba3c44a449b8b7cac862f4f81e
 DIST scummvm-2.5.0.tar.xz 130095472 BLAKE2B a5153280999e321be5bf7b56411c163d5ba1d4fb142fc900e1c3cb709d357d199d3764a94af57ab7218ee201bdbe6288adf222add9ffc941324b84d0e6954fe8 SHA512 7ea702cf0f993994209fd692e82ab65f9686fb60d65f36624a31bd642067fe7dd35e556666281c68d1592d7dd07333f085c124038f7a45acefae8f30bceff534
 DIST scummvm-2.5.1.tar.xz 132828412 BLAKE2B 08fb2fa6cbeec3c1ec24a9b660aab4344f0dbcf4c42655392315aef0ce78105b2a669ef9c82fc09bc389856e592e4e5249d84512b288e7d790914d5caee3972d SHA512 5e5aaf247e26434dd1594547a3066dce6f52e12370532b8bff09ae22149d697f6d3ab0a94b5c1cf578b2b8cba32d1cd6e5dc30fe0cd6266c8f2b23cba13d7d03
+DIST scummvm-2.6.0.tar.xz 141331920 BLAKE2B 38cdce3e9b7954347d3ba05946c607aa5a62aa8fa1c2145030c1667632a4da43afd3f14ed19ebaf664bbf521610b2cfccc739c82dae95650572bfab81495cb80 SHA512 6bb2b22f9b11a8de2eaa48c520d63579f4907fa49d8b02d58702ece86945b38ea911376f5ae0dc6f3b6ed794ff32ca51fbf690e341401b4a03276b32e9bd7b69

games-engines/scummvm/scummvm-2.6.0.ebuild

@@ -0,0 +1,138 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit desktop flag-o-matic toolchain-funcs xdg
+
+DESCRIPTION="Reimplementation of the SCUMM game engine used in Lucasarts adventures"
+HOMEPAGE="https://www.scummvm.org/"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/scummvm/scummvm"
+else
+	SRC_URI="https://downloads.scummvm.org/frs/scummvm/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}/${PN}-${P}"
+fi
+
+LICENSE="GPL-2+ LGPL-2.1 BSD GPL-3-with-font-exception"
+SLOT="0"
+IUSE="a52 aac alsa debug flac fluidsynth fribidi gif +gtk jpeg lua mpeg2 mp3 +net opengl png sndio speech theora truetype unsupported vorbis zlib"
+RESTRICT="test"  # it only looks like there's a test there #77507
+
+RDEPEND="
+	>=media-libs/libsdl2-2.0.0[sound,joystick,video]
+	a52? ( media-libs/a52dec )
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	fluidsynth? ( media-sound/fluidsynth:= )
+	fribidi? ( dev-libs/fribidi )
+	gif? ( media-libs/giflib )
+	gtk? (
+		dev-libs/glib:2
+		x11-libs/gtk+:3
+	)
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	mp3? ( media-libs/libmad )
+	mpeg2? ( media-libs/libmpeg2 )
+	net? (
+		media-libs/sdl2-net
+		net-misc/curl
+	)
+	opengl? (
+		|| (
+			virtual/opengl
+			media-libs/mesa[gles2]
+			media-libs/mesa[gles1]
+		)
+	)
+	png? ( media-libs/libpng:0 )
+	sndio? ( media-sound/sndio:= )
+	speech? ( app-accessibility/speech-dispatcher )
+	truetype? ( media-libs/freetype:2 )
+	theora? ( media-libs/libtheora )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	zlib? ( sys-libs/zlib:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-arch/xz-utils
+	truetype? ( virtual/pkgconfig )
+	x86? ( dev-lang/nasm )
+"
+
+S="${WORKDIR}/${P/_/}"
+
+src_prepare() {
+	default
+
+	# -g isn't needed for nasm here
+	sed -i \
+		-e '/NASMFLAGS/ s/-g//' \
+		configure || die
+	sed -i \
+		-e '/INSTALL.*doc/d' \
+		-e '/INSTALL.*\/pixmaps/d' \
+		-e 's/-s //' \
+		ports.mk || die
+}
+
+src_configure() {
+	use x86 && append-ldflags -Wl,-z,noexecstack
+	tc-export STRINGS
+
+	local myconf=(
+		--backend=sdl
+		--host=${CHOST}
+		--enable-verbose-build
+		--prefix="${EPREFIX}/usr"
+		--libdir="${EPREFIX}/usr/$(get_libdir)"
+		--opengl-mode=$(usex opengl auto none)
+		--with-sdl-prefix="${EPREFIX}/usr"
+		$(use_enable a52)
+		$(use_enable aac faad)
+		$(use_enable alsa)
+		$(use_enable debug)
+		$(use_enable !debug release-mode)
+		$(use_enable flac)
+		$(usex fluidsynth '' --disable-fluidsynth)
+		$(use_enable fribidi)
+		$(use_enable gif)
+		$(use_enable gtk)
+		$(use_enable jpeg)
+		$(use_enable lua)
+		$(use_enable mp3 mad)
+		$(use_enable mpeg2)
+		$(use_enable net libcurl)
+		$(use_enable net sdlnet)
+		$(use_enable png)
+		$(use_enable sndio)
+		$(use_enable speech tts)
+		$(use_enable theora theoradec)
+		$(use_enable truetype freetype2)
+		$(usex unsupported --enable-all-engines '')
+		$(use_enable vorbis)
+		$(use_enable zlib)
+		$(use_enable x86 nasm)
+	)
+	echo "configure ${myconf[@]}"
+	# NOT AN AUTOCONF SCRIPT SO DONT CALL ECONF
+	SDL_CONFIG="sdl2-config" \
+	./configure "${myconf[@]}" ${EXTRA_ECONF} || die
+}
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR) cru" \
+		RANLIB="$(tc-getRANLIB)"
+}
+
+src_install() {
+	default
+	doicon -s scalable icons/scummvm.svg
+}

games-engines/scummvm/scummvm-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -34,7 +34,7 @@ RDEPEND="
 		dev-libs/glib:2
 		x11-libs/gtk+:3
 	)
-	jpeg? ( virtual/jpeg:0 )
+	jpeg? ( media-libs/libjpeg-turbo:= )
 	mp3? ( media-libs/libmad )
 	mpeg2? ( media-libs/libmpeg2 )
 	net? (