sci-visualization/gwyddion: Version bump to 2.47, EAPI bump 5 -> 6

Package-Manager: portage-2.3.0
Closes: gentoo#3688
Signed-off-by: Guilherme Amadio <[email protected]>

sci-visualization/gwyddion/Manifest

@@ -1 +1,2 @@
 DIST gwyddion-2.44.tar.xz 3517624 SHA256 e7ee7545770a276e78fdff1b51e547d5d0ba39b94995da91e0d6797122b7eda5 SHA512 c80a0e4e9dde2f669763629d34dacc0015770c4704a10fc820f4d8e75b4f4275852162653f0c6c52674ed76162861af860de6741466d939066bfea3fb584d2ff WHIRLPOOL 56f78efb477da520a65473ce6be9eff88897198e8a80e5971a2280755fdc61925405c0a464572cf7887689746d140eefc855562569919bc17e057f472ac0b597
+DIST gwyddion-2.47.tar.xz 3974120 SHA256 e948abb3d281d49d3684e4c15d88c424dde11c71647bdbbba0a1d9fce74fa656 SHA512 a6bbda2d32ec013a9d6c7e2b6dbf2cef08d8f964099c0fda511bc92c16c943459f29d52f784a599466af65027aaae3aaeb1b79e56c40e39bc47019044eecd3e6 WHIRLPOOL a244f0ccb6e3ba7d53401df89c1a7279d6d21196c09b89da71a6a979c410f0b88a1f064da8c8a5d49629a7ef8d449ce2ec673e631bf486178f5435127ae8efdd

sci-visualization/gwyddion/gwyddion-2.47.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit fdo-mime gnome2-utils python-single-r1
+
+DESCRIPTION="Framework for Scanning Mode Microscopy data analysis"
+HOMEPAGE="http://gwyddion.net/"
+SRC_URI="http://gwyddion.net/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc fits fftw gnome kde nls opengl perl python ruby sourceview xml X"
+
+RDEPEND="
+	media-libs/libpng:0=
+	x11-libs/cairo
+	x11-libs/gtk+:2
+	x11-libs/libXmu
+	x11-libs/pango
+	fits? ( sci-libs/cfitsio )
+	fftw? ( sci-libs/fftw:3.0= )
+	gnome? ( gnome-base/gconf:2 )
+	kde? ( kde-frameworks/kdelibs:4 )
+	opengl? ( virtual/opengl x11-libs/gtkglext )
+	perl? ( dev-lang/perl:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygtk:2[${PYTHON_USEDEP}]
+	)
+	ruby? ( dev-ruby/narray )
+	sourceview? ( x11-libs/gtksourceview:2.0 )
+	xml? ( dev-libs/libxml2:2 )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	econf \
+		--disable-rpath \
+		$(use_enable doc gtk-doc) \
+		$(use_enable nls) \
+		$(use_enable python pygwy) \
+		$(use_enable fits cfitsio) \
+		$(use_with perl) \
+		$(use_with python) \
+		$(use_with ruby) \
+		$(use_with fftw fftw3) \
+		$(use_with opengl gl) \
+		$(use_with sourceview gtksourceview) \
+		$(use_with xml libxml2) \
+		$(use_with X x) \
+		$(use_with kde kde4-thumbnailer)
+}
+
+src_install() {
+	default
+	use python && dodoc modules/pygwy/README.pygwy
+}
+
+pkg_postinst() {
+	use gnome && gnome2_gconf_install
+	fdo-mime_desktop_database_update
+}
+
+pkg_prerm() {
+	use gnome && gnome2_gconf_uninstall
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}