Skip to content

Commit

Permalink
games-simulation/openrct2: add 0.4.9
Browse files Browse the repository at this point in the history
Signed-off-by: Conrad Kostecki <[email protected]>
  • Loading branch information
ConiKost committed Mar 3, 2024
1 parent e42179a commit bd93ffc
Show file tree
Hide file tree
Showing 2 changed files with 184 additions and 0 deletions.
4 changes: 4 additions & 0 deletions games-simulation/openrct2/Manifest
Original file line number Diff line number Diff line change
@@ -1,7 +1,11 @@
DIST openrct2-0.4.7.tar.gz 21677290 BLAKE2B 934f26bd2117f4c5be1a20e5eff10a07a260a5f01d1df2f95f2a4b66adf603868e5ea33a88398857f35851575c38f28e6c98b7912ebe0cc3c97b745cbb280b02 SHA512 704007298d35b90cba592719649d066a2e8e546044f39ca0edddebd4c9e8e864ef8d1314e3bc5eaadf38fb2df54d9cb33ee9cb1cba3defd099aa34ea2a985a90
DIST openrct2-0.4.8.tar.gz 21699121 BLAKE2B 07517be3430f70001001866aee3c488aa5618c48f342c2b93ccfd29f69f4ea73b769ffea70c11a8f8f0dafd143569852469dc7b074524f2f17957927eb804661 SHA512 5035eff3cef4f05e60d3ac0ab76648cbda4553068ba44c81faec2344e6665c5bf6319ddb5f336c20f49369cefd0378aa725da10824217d6af5be81b99f660b9f
DIST openrct2-0.4.9.tar.gz 21819673 BLAKE2B 32fa5b3a8a8e0b4a7031fcbca6ad419e5efe0812713d58d9e40880e3747671ca70ef6285536a335eba59aba41e3c9a238b55577796bd1c931b8e3c1fb99fff38 SHA512 711254007f8ed7377d6ceedcedf6e75d5a07033844dba891cc5c1f457d60a45ae4430d57f17624a5dce6d157d7ed269d235c53eedd46d58c433791d749953d85
DIST openrct2-objects-1.3.13.zip 4708920 BLAKE2B 16540805a0a9413de96837d23787ed47a84e570b2fa2480c89f4f9a644033c39ffa9167838c164511308942401fd054f2091362491a395c207bb3b779e7a740c SHA512 9e285cf922adb5b4d7c79f06cc7445e05bc755968099dc83fc62b411875bfe1e39a087559dc1730b44e78133f4c642da316fd94e7f0877189c59517e8bc1038f
DIST openrct2-objects-1.4.0.zip 5314707 BLAKE2B ae934f91f1de376851f37d37227049e90dcf644eab1bde4544b3a02ba1b678a3f27c49e106860db0f6817986301b95a1121be4827be06e05faf2c1b1583e953f SHA512 996cd4f6b5a3df1acd8258c68a123968e436b41e667e0d1f3a3e5b53d9f1788d1f8b3b87b4e8bbe3b1aff856449eca3bf04916e6a2bdca497e0de89807b90b3b
DIST openrct2-openmusic-1.5.zip 40548101 BLAKE2B 11cf46a54716097038e134ae11aeb23823097ca96189dabeb0e43d7050d5e776aa309c38de247da15b1eec7ed6be6299d5673a92df1323cc3a4a5bbc4f48d567 SHA512 55d4afb854eaa5a69c42e7f0b26669c8fb58b2eba3e2892c655e76d8fab82e2734f39981d7f5ac69e11dc87d06c89795da2468feac3bc53ef6cfdd992e3924f3
DIST openrct2-opensound-1.0.3.zip 3820122 BLAKE2B 74265800595e36ac943bf2ee5d9c8f6cb3bbd5be3713d9590cb81faac4a75154dfbf9806b1b55e9c2426c84e3cf313a6271fc378ebfd4fa94821683157be5470 SHA512 89784703fb2cda67b5440e06381b44e59ce4a42a88004761c76f0c2b23f78be3692e5fe5e2c8655943e04f7a45e479cfcbc2c3998202222dab16a092b9a73195
DIST openrct2-opensound-1.0.5.zip 4012384 BLAKE2B 7ddb1437d7e68373f05bd60d77f03971b8a1d6f4280d008d5bf3e86b5d2cb46001a04edddeeb04a06a37801c3afbd35926beb54fe5a72c7fa88b50d0a0b18535 SHA512 fc46ffb3f6243b3d783a280481ce373a8ddc8cf1fd28bfeceecf6223b72b38f1d49d0c95eea3376308a61a77c50c7a06252b6d72248cfecc493b63b65bd6512a
DIST openrct2-replays-0.0.78.zip 1829988 BLAKE2B cf11a05f6ba5a2808cd4c016ac3c7537a0b49b67fd5ef5ab705aebd4ddc64dd4a82ea12d9c082fe66cebb57437c0d81052bcddfb94a0c9f7aab024a82c2e2ca8 SHA512 c6ff18c2206192ed4fb56535732137229f9bced96da00037d691bc64dcdb102cffe37f180054319e7c8ef8dbbd7de49792c3a7e845199fa180612ed97a149b32
DIST openrct2-replays-0.0.79.zip 1934633 BLAKE2B 4b5c4d96be91055ceff8f5f5f1a894cc2544659983e61ac2f42d655229357b6a368553c1ee45d147cb360c8d54bb0ca78b61a9716efa8d1d7f37cd7c5ba50fa7 SHA512 04acde4d60c8fa949b298dd15e38fe0421659357fa214dffb0577574e0b0ac218a01ce998f4e12e3ab13a88fbbba8096392462fda29c68a6215bc0875aaae9b2
DIST openrct2-title-sequences-0.4.6.zip 2547725 BLAKE2B 5f7b36cd1372106923000775307ea7ff8c142c3b1d026d84b86f255a629b0a2ac16a682300999789229a8833d4c7327c858c04710ecddfb97af1858ff121a5c4 SHA512 bd7d0f25047540572be75a4a8886e8dabdceb7a3e11fdeb5473b66fe804d829acdb763d34ec7cfa656df9bc527268a3e0e7ca09c699995804b22ff2a529ad5da
180 changes: 180 additions & 0 deletions games-simulation/openrct2/openrct2-0.4.9.ebuild
Original file line number Diff line number Diff line change
@@ -0,0 +1,180 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake readme.gentoo-r1 xdg-utils

MY_PN="OpenRCT2"
MY_PN_MSX="openmusic"
MY_PN_OBJ="objects"
MY_PN_RPL="replays"
MY_PN_SFX="opensound"
MY_PN_TS="title-sequences"
MY_PV_MSX="1.5"
MY_PV_OBJ="1.4.0"
MY_PV_RPL="0.0.79"
MY_PV_SFX="1.0.5"
MY_PV_TS="0.4.6"

DESCRIPTION="An open source re-implementation of Chris Sawyer's RollerCoaster Tycoon 2"
HOMEPAGE="https://openrct2.org/"
SRC_URI="
https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
https://github.com/${MY_PN}/${MY_PN_MSX}/releases/download/v${MY_PV_MSX}/${MY_PN_MSX}.zip -> ${PN}-${MY_PN_MSX}-${MY_PV_MSX}.zip
https://github.com/${MY_PN}/${MY_PN_OBJ}/releases/download/v${MY_PV_OBJ}/${MY_PN_OBJ}.zip -> ${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}.zip
https://github.com/${MY_PN}/OpenSoundEffects/releases/download/v${MY_PV_SFX}/${MY_PN_SFX}.zip -> ${PN}-${MY_PN_SFX}-${MY_PV_SFX}.zip
https://github.com/${MY_PN}/${MY_PN_TS}/releases/download/v${MY_PV_TS}/${MY_PN_TS}.zip -> ${PN}-${MY_PN_TS}-${MY_PV_TS}.zip
test? ( https://github.com/${MY_PN}/${MY_PN_RPL}/releases/download/v${MY_PV_RPL}/${MY_PN_RPL}.zip -> ${PN}-${MY_PN_RPL}-${MY_PV_RPL}.zip )
"
S="${WORKDIR}/${MY_PN}-${PV}"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
IUSE="dedicated +flac +opengl scripting test +truetype +vorbis"
RESTRICT="!test? ( test )"

COMMON_DEPEND="
dev-libs/icu:=
dev-libs/jansson:=
dev-libs/libzip:=
media-libs/libpng:=
net-misc/curl[ssl]
sys-libs/zlib
!dedicated? (
media-libs/libsdl2
media-libs/speexdsp
flac? ( media-libs/flac:= )
opengl? ( virtual/opengl )
vorbis? ( media-libs/libvorbis )
)
dev-libs/openssl:0=
scripting? ( dev-lang/duktape:= )
truetype? (
media-libs/fontconfig:1.0
media-libs/freetype:2
)
"

RDEPEND="
${COMMON_DEPEND}
dedicated? (
acct-group/openrct2
acct-user/openrct2
)
"

DEPEND="
${COMMON_DEPEND}
dev-cpp/nlohmann_json
test? ( dev-cpp/gtest )
"

BDEPEND="
app-arch/unzip
virtual/pkgconfig
"

PATCHES=(
"${FILESDIR}/${PN}-0.4.0-include-additional-paths.patch"
"${FILESDIR}/${PN}-0.4.1-gtest-1.10.patch"
)

src_unpack() {
unpack "${P}".tar.gz

mkdir -p "${S}"/data || die
cd "${S}"/data
unpack "${PN}-${MY_PN_MSX}-${MY_PV_MSX}".zip
unpack "${PN}-${MY_PN_SFX}-${MY_PV_SFX}".zip

mkdir -p "${S}"/data/object || die
cd "${S}"/data/object || die
unpack "${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}".zip

mkdir -p "${S}"/data/sequence || die
cd "${S}"/data/sequence || die
unpack "${PN}-${MY_PN_TS}-${MY_PV_TS}".zip

if use test; then
mkdir -p "${S}"/testdata/replays || die
cd "${S}"/testdata/replays || die
unpack "${PN}-${MY_PN_RPL}-${MY_PV_RPL}".zip
fi
}

src_prepare() {
cmake_src_prepare

# Don't treat warnings as errors.
sed -e 's/-Werror//' -i CMakeLists.txt || die
}

src_configure() {
# Note: There is currently no support for Disord-RPC and Google Benchmark,
# as both packages do not exist in Gentoo, so support for them has been disabled.
local mycmakeargs=(
-DDISABLE_DISCORD_RPC=ON
$(usex !dedicated "-DDISABLE_FLAC=$(usex !flac)" "")
-DDISABLE_GOOGLE_BENCHMARK=ON
-DDISABLE_GUI=$(usex dedicated)
-DDISABLE_HTTP=OFF
-DDISABLE_IPO=ON
-DDISABLE_NETWORK=OFF
$(usex !dedicated "-DDISABLE_OPENGL=$(usex !opengl)" "")
-DDISABLE_TTF=$(usex !truetype)
$(usex !dedicated "-DDISABLE_VORBIS=$(usex !vorbis)" "")
-DDOWNLOAD_OBJECTS=OFF
-DDOWNLOAD_OPENMSX=OFF
-DDOWNLOAD_OPENSFX=OFF
-DDOWNLOAD_REPLAYS=OFF
-DDOWNLOAD_TITLE_SEQUENCES=OFF
-DENABLE_SCRIPTING=$(usex scripting)
-DOPENRCT2_USE_CCACHE=OFF
-DPORTABLE=OFF
-DSTATIC=OFF
-DWITH_TESTS=$(usex test)
-DUSE_MMAP=ON
)

cmake_src_configure
}

src_test() {
# Since the tests need the OpenRCT2 data,
# we need to symlink them into the build directory,
# otherwise some tests will fail, as they don't find the OpenRCT2 data.
# It is currently not possible to override that path.
# See: https://github.com/OpenRCT2/OpenRCT2/issues/6473
ln -s "${S}"/data "${BUILD_DIR}" || die

cmake_src_test
}

src_install() {
use scripting && DOCS+=( "distribution/scripting.md" "distribution/openrct2.d.ts" )

cmake_src_install

if use dedicated; then
newinitd "${FILESDIR}"/openrct2.initd openrct2
newconfd "${FILESDIR}"/openrct2.confd openrct2
fi

readme.gentoo_create_doc
}

pkg_postinst() {
readme.gentoo_print_elog

xdg_desktop_database_update
xdg_icon_cache_update
xdg_mimeinfo_database_update
}

pkg_postrm() {
xdg_desktop_database_update
xdg_icon_cache_update
xdg_mimeinfo_database_update
}

0 comments on commit bd93ffc

Please sign in to comment.