net-wireless/qdmr: add 0.12.0

Additional minor QA
Upstream fixed bug 907943 in this release.
Closes: https://bugs.gentoo.org/907943

Signed-off-by: Rick Farina <[email protected]>

net-wireless/qdmr/Manifest

@@ -2,3 +2,4 @@ DIST qdmr-0.10.2.tar.gz 5903169 BLAKE2B 1ef4e9846dd4206d1eae3cfb5562fccec24b156b
 DIST qdmr-0.10.4.tar.gz 6013877 BLAKE2B 32da2984620e162e049f4017e29bff7d500f293fa6125246fdd2e7640ed9dd1e0e066c03297c365b9b5dc2e76dee1e1511fed327690c9a611fd7aa1abc26f988 SHA512 4ba75274bcaa4a7b8887edf7a1725863ee4dc00730d9386673b5c149e7ac30a32f06b7341ebd327cae337eac7a445999a17606cbbb22734216df2c14cb03c322
 DIST qdmr-0.11.2.tar.gz 6391759 BLAKE2B d45c934a0bad8c92a10a1f183007310137c8ad04a95f5f1471bac2a54f7f33e3af44b386e4ff2803a42934b575ce2e414bb6090a7e474e7aa1ac82b1d722598e SHA512 cd8dfc9eb9d6efad08efcaaa7b6e2ae61823982bd2ffa7bc41826c9fea3c21bd63f5a2114dc63d88e01a0c56f2fb615cbe0ddef62b87deebb798beda937de5d0
 DIST qdmr-0.11.3.tar.gz 6577404 BLAKE2B 7f9133e9620c5286492ee813907c47d550eba9368e801cd3939897381ed751788fa43337dbeb2cd1be5c4765c554ac5a031d9b4965c49dd1a521949d74b6f9f2 SHA512 4bb62cd84e8cce02f6582f854c4247c91f30271cc96856a4d1a55a4dbea5d2d9639e9db2df8b76f2ff196dddac1d7de3632627890617688037bd78085422e75e
+DIST qdmr-0.12.0.tar.gz 6905942 BLAKE2B 4452120860c8e4cc8e720161d90dd090affe43fa15965895e2e088f94856675811d3685933f25493b00eb2157ff58bef5481cb705cd92e7c9ef94a61fc877bdb SHA512 5cdb41c5d0234f8c1d4cfc4f75ea4e832c94f692320fe7714df1d0e893379b2c0939e004779a71cb601e696133d94d083d4e6062ab31916e9431bd14f6a60b6a

net-wireless/qdmr/qdmr-0.12.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev linux-info
+
+DESCRIPTION="GUI application for configuring and programming cheap DMR radios"
+HOMEPAGE="https://dm3mat.darc.de/qdmr/"
+if [ "${PV}" = "9999" ]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/hmatuschek/qdmr.git"
+else
+	MY_PV="${PV/_/-}"
+	SRC_URI="https://github.com/hmatuschek/qdmr/archive/refs/tags/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	KEYWORDS="~amd64 ~x86"
+fi
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/yaml-cpp:=
+	dev-qt/qtwidgets:5
+	dev-qt/qtgui:5
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtpositioning:5
+	dev-qt/qtserialport:5
+	virtual/libusb:1
+"
+DEPEND="${RDEPEND}
+	dev-qt/designer:5
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="dev-qt/linguist-tools:5"
+
+pkg_setup() {
+	CONFIG_CHECK="~USB_ACM"
+	WARNING_USB_ACM="You need to enable CONFIG_USB_ACM in your kernel to talk to some radios"
+	CONFIG_CHECK="~USB_SERIAL"
+	WARNING_USB_SERIAL="You need to enable CONFIG_USB_SERIAL in your kernel to talk to some radios"
+	check_extra_config
+}
+
+src_prepare() {
+	sed -i "s#/etc/udev/rules.d/#$(get_udevdir)/rules.d#" lib/CMakeLists.txt
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}

net-wireless/qdmr/qdmr-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 2021-2023 Gentoo Authors
+# Copyright 2021-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -16,11 +16,10 @@ else
 	S="${WORKDIR}/${PN}-${MY_PV}"
 	KEYWORDS="~amd64 ~x86"
 fi
-IUSE="test"
-RESTRICT="!test? ( test )"
-
 LICENSE="GPL-3+"
 SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
 
 RDEPEND="
 	dev-cpp/yaml-cpp:=
@@ -40,9 +39,9 @@ BDEPEND="dev-qt/linguist-tools:5"
 
 pkg_setup() {
 	CONFIG_CHECK="~USB_ACM"
-	WARNING_USB_ACM="Some radios require CONFIG_USB_ACM to work, you may need to enable this driver to talk to your radio"
+	WARNING_USB_ACM="You need to enable CONFIG_USB_ACM in your kernel to talk to some radios"
 	CONFIG_CHECK="~USB_SERIAL"
-	WARNING_USB_SERIAL="Some radios require CONFIG_USB_SERIAL to work, you may need to enable this driver to talk to your radio"
+	WARNING_USB_SERIAL="You need to enable CONFIG_USB_SERIAL in your kernel to talk to some radios"
 	check_extra_config
 }