forked from gentoo/gentoo
-
Notifications
You must be signed in to change notification settings - Fork 0
Commit
This commit does not belong to any branch on this repository, and may belong to a fork outside of the repository.
sys-kernel/vanilla-kernel: Bump to 5.10.42
Signed-off-by: Michał Górny <[email protected]>
- Loading branch information
Showing
2 changed files
with
104 additions
and
0 deletions.
There are no files selected for viewing
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
102 changes: 102 additions & 0 deletions
102
sys-kernel/vanilla-kernel/vanilla-kernel-5.10.42.ebuild
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
| Original file line number | Diff line number | Diff line change |
|---|---|---|
| @@ -0,0 +1,102 @@ | ||
| # Copyright 2020-2021 Gentoo Authors | ||
| # Distributed under the terms of the GNU General Public License v2 | ||
|
|
||
| EAPI=7 | ||
|
|
||
| inherit kernel-build verify-sig | ||
|
|
||
| MY_P=linux-${PV} | ||
| # https://koji.fedoraproject.org/koji/packageinfo?packageID=8 | ||
| CONFIG_VER=5.10.12 | ||
| CONFIG_HASH=836165dd2dff34e4f2c47ca8f9c803002c1e6530 | ||
| GENTOO_CONFIG_VER=5.10.32 | ||
|
|
||
| DESCRIPTION="Linux kernel built from vanilla upstream sources" | ||
| HOMEPAGE="https://www.kernel.org/" | ||
| SRC_URI+=" https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz | ||
| https://github.com/mgorny/gentoo-kernel-config/archive/v${GENTOO_CONFIG_VER}.tar.gz | ||
| -> gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz | ||
| verify-sig? ( | ||
| https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.sign | ||
| ) | ||
| amd64? ( | ||
| https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-x86_64-fedora.config | ||
| -> kernel-x86_64-fedora.config.${CONFIG_VER} | ||
| ) | ||
| arm64? ( | ||
| https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-aarch64-fedora.config | ||
| -> kernel-aarch64-fedora.config.${CONFIG_VER} | ||
| ) | ||
| ppc64? ( | ||
| https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-ppc64le-fedora.config | ||
| -> kernel-ppc64le-fedora.config.${CONFIG_VER} | ||
| ) | ||
| x86? ( | ||
| https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-i686-fedora.config | ||
| -> kernel-i686-fedora.config.${CONFIG_VER} | ||
| )" | ||
| S=${WORKDIR}/${MY_P} | ||
|
|
||
| LICENSE="GPL-2" | ||
| KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86" | ||
| IUSE="debug" | ||
| REQUIRED_USE=" | ||
| arm? ( savedconfig )" | ||
|
|
||
| RDEPEND=" | ||
| !sys-kernel/vanilla-kernel-bin:${SLOT}" | ||
| BDEPEND=" | ||
| debug? ( dev-util/pahole ) | ||
| verify-sig? ( app-crypt/openpgp-keys-kernel )" | ||
| PDEPEND=" | ||
| >=virtual/dist-kernel-${PV}" | ||
|
|
||
| VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/kernel.org.asc | ||
|
|
||
| src_unpack() { | ||
| if use verify-sig; then | ||
| einfo "Unpacking linux-${PV}.tar.xz ..." | ||
| verify-sig_verify_detached - "${DISTDIR}"/linux-${PV}.tar.sign \ | ||
| < <(xz -cd "${DISTDIR}"/linux-${PV}.tar.xz | tee >(tar -x)) | ||
| assert "Unpack failed" | ||
| unpack "gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz" | ||
| else | ||
| default | ||
| fi | ||
| } | ||
|
|
||
| src_prepare() { | ||
| default | ||
|
|
||
| # prepare the default config | ||
| case ${ARCH} in | ||
| amd64) | ||
| cp "${DISTDIR}/kernel-x86_64-fedora.config.${CONFIG_VER}" .config || die | ||
| ;; | ||
| arm) | ||
| return | ||
| ;; | ||
| arm64) | ||
| cp "${DISTDIR}/kernel-aarch64-fedora.config.${CONFIG_VER}" .config || die | ||
| ;; | ||
| ppc64) | ||
| cp "${DISTDIR}/kernel-ppc64le-fedora.config.${CONFIG_VER}" .config || die | ||
| ;; | ||
| x86) | ||
| cp "${DISTDIR}/kernel-i686-fedora.config.${CONFIG_VER}" .config || die | ||
| ;; | ||
| *) | ||
| die "Unsupported arch ${ARCH}" | ||
| ;; | ||
| esac | ||
|
|
||
| echo 'CONFIG_LOCALVERSION="-dist"' > "${T}"/version.config || die | ||
| local merge_configs=( | ||
| "${T}"/version.config | ||
| "${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"/base.config | ||
| ) | ||
| use debug || merge_configs+=( | ||
| "${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"/no-debug.config | ||
| ) | ||
| kernel-build_merge_configs "${merge_configs[@]}" | ||
| } |