Skip to content

Commit

Permalink
kde-plasma/kwin: Scoop up fixes from 6.1 branch
Browse files Browse the repository at this point in the history 
Akseli Lahtinen (1):
      WindowHeapDelegate: label topMargin to small, remove height padding

Vlad Zahorodnii (4):
      plugins/screencast: Handle frame rate throttling timer firing a bit earlier
      plugins/screencast: Prefer glReadnPixels() and glGetnTexImage()
      opengl: Add OpenGlContext::glGetnTexImage()
      wayland: add error handling for QFile::open failure in org_kde_plasma_window_get_icon

Xaver Hugl (3):
      backends/drm: disable triple buffering on NVidia
      plugins/glide: drop references to closed windows if they're not animated
      placement: ignore the active output with place under mouse

Signed-off-by: Andreas Sturmlechner <[email protected]>
  • Loading branch information
@a17r
a17r committed Jul 8, 2024
1 parent cdce71b commit bf898b6
Show file tree
Hide file tree
Showing 2 changed files with 148 additions and 0 deletions.
1 change: 1 addition & 0 deletions kde-plasma/kwin/Manifest
View file
Original file line number Diff line number Diff line change
@@ -1,2 +1,3 @@
DIST kwin-5.27.11.tar.xz 7644856 BLAKE2B a21fa8d60418bf109b3f651f266185b1e97bdc92e7c7d7ab4b73271d91e8c2b629fd22851b3fff88d7ecd8277fdd8a70bf1c3bd93aa1e379377b86f56cfe2bd2 SHA512 8c76695f71ce67142d16ad16aed342375ae3aefa59ff2628a28003025701bc6b48999adaac79fc5ab09ec22c8d8407fc29f011fd3da6f992c36531fd6c3fc37b
DIST kwin-6.1.2-patchset.tar.xz 6164 BLAKE2B c39c81011c59149a170ceb3dbbb5603d8d2c2b257ab0ad1f0ff21cadf41239434c1b398b6bb1a34ecd73cef0ee429ce5df847dbf204c0d5941e794be0bbcf412 SHA512 00819eff7e463529e1229964c35369c6f041737ccdf1ac51311942693e1816d80405eac42b2e74e1995c4b60d5fb038b200a0e43bef3c44d225e06029a605d21
DIST kwin-6.1.2.tar.xz 8493112 BLAKE2B 54bca1632a8c1e31317ab2c7de763a7bb2629121283e84110a0b0a3ac96532e62083f9e715c828d311d8d7d9c1403032be109afe0fb77fc78d8f8ed21b215005 SHA512 cd138846c985ad415ef8fe070034da7887bfd0f31641f2ef5d52e8a0f4c9d00d759c6dcbeaa21b2e482c145f357cc6548476aae53d3eab8654a5b0175eeedc0e
147 changes: 147 additions & 0 deletions kde-plasma/kwin/kwin-6.1.2-r1.ebuild
View file
Original file line number Diff line number Diff line change
@@ -0,0 +1,147 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ECM_HANDBOOK="optional"
ECM_TEST="true"
KFMIN=6.3.0
PVCUT=$(ver_cut 1-3)
QTMIN=6.7.1
inherit ecm plasma.kde.org

DESCRIPTION="Flexible, composited Window Manager for windowing systems on Linux"
PATCHSET="${P}-patchset"
SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${PATCHSET}.tar.xz"

LICENSE="GPL-2+"
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~riscv"
IUSE="accessibility +caps gles2-only lock screencast +shortcuts systemd"

RESTRICT="test"

# qtbase slot op: GuiPrivate use in tabbox
COMMON_DEPEND="
dev-libs/libei
>=dev-libs/libinput-1.19:=
>=dev-libs/wayland-1.22.0
>=dev-qt/qt5compat-${QTMIN}:6[qml]
>=dev-qt/qtbase-${QTMIN}:6=[accessibility=,gles2-only=,gui,libinput,opengl,widgets]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=dev-qt/qtsensors-${QTMIN}:6
>=dev-qt/qtshadertools-${QTMIN}:6
>=kde-frameworks/kauth-${KFMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kcolorscheme-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6[qml]
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kdeclarative-${KFMIN}:6
>=kde-frameworks/kglobalaccel-${KFMIN}:6=[X(+)]
>=kde-frameworks/kguiaddons-${KFMIN}:6[wayland]
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kidletime-${KFMIN}:6=[wayland]
>=kde-frameworks/knewstuff-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kpackage-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/ksvg-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6=[wayland,X]
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-plasma/breeze-${PVCUT}:6
>=kde-plasma/kdecoration-${PVCUT}:6
>=kde-plasma/kwayland-${PVCUT}:6
>=kde-plasma/plasma-activities-${PVCUT}:6
media-libs/fontconfig
media-libs/freetype
media-libs/lcms:2
media-libs/libdisplay-info:=
media-libs/libepoxy
media-libs/libglvnd
>=media-libs/mesa-21.3[egl(+),gbm(+),wayland,X]
virtual/libudev:=
x11-libs/libX11
x11-libs/libXi
>=x11-libs/libdrm-2.4.116
>=x11-libs/libxcb-1.10:=
>=x11-libs/libxcvt-0.1.1
>=x11-libs/libxkbcommon-1.5.0
x11-libs/xcb-util-cursor
x11-libs/xcb-util-keysyms
x11-libs/xcb-util-wm
accessibility? ( media-libs/libqaccessibilityclient:6 )
gles2-only? ( || (
>=media-libs/mesa-24.1.0_rc1[opengl]
<media-libs/mesa-24.1.0_rc1[gles2]
) )
lock? ( >=kde-plasma/kscreenlocker-${PVCUT}:6 )
screencast? ( >=media-video/pipewire-0.3:= )
shortcuts? ( >=kde-plasma/kglobalacceld-${PVCUT}:6 )
"
RDEPEND="${COMMON_DEPEND}
!kde-plasma/kdeplasma-addons:5
!kde-plasma/kwayland-server
>=dev-qt/qtmultimedia-${QTMIN}:6[qml]
|| (
dev-qt/qtmultimedia:6[ffmpeg]
(
dev-qt/qtmultimedia:6[gstreamer]
media-plugins/gst-plugins-soup:1.0
)
)
>=kde-frameworks/kirigami-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-plasma/libplasma-${PVCUT}:6[wayland(+)]
sys-apps/hwdata
x11-base/xwayland[libei]
"
DEPEND="${COMMON_DEPEND}
>=dev-libs/plasma-wayland-protocols-1.13.0
>=dev-libs/wayland-protocols-1.34
>=dev-qt/qttools-${QTMIN}:6[widgets]
>=dev-qt/qtbase-${QTMIN}:6[concurrent]
>=dev-qt/qtwayland-${QTMIN}:6
x11-base/xorg-proto
x11-libs/xcb-util-image
caps? ( sys-libs/libcap )
test? ( screencast? ( >=kde-plasma/kpipewire-${PVCUT}:6 ) )
"
BDEPEND="
>=dev-qt/qtwayland-${QTMIN}:6
dev-util/wayland-scanner
>=kde-frameworks/kcmutils-${KFMIN}:6
"
PDEPEND=">=kde-plasma/kde-cli-tools-${PVCUT}:*"

PATCHES=( "${WORKDIR}/${PATCHSET}" )

src_prepare() {
ecm_src_prepare

# TODO: try to get a build switch upstreamed
if ! use screencast; then
sed -e "s/^pkg_check_modules.*PipeWire/#&/" -i CMakeLists.txt || die
fi

# TODO: try to get a build switch upstreamed
if ! use systemd; then
sed -e "s/^pkg_check_modules.*libsystemd/#&/" -i CMakeLists.txt || die
fi
}

src_configure() {
local mycmakeargs=(
# TODO: KWIN_BUILD_X11?
# KWIN_BUILD_NOTIFICATIONS exists, but kdeclarative still hard-depends on it
$(cmake_use_find_package accessibility QAccessibilityClient6)
$(cmake_use_find_package caps Libcap)
-DKWIN_BUILD_SCREENLOCKER=$(usex lock)
-DKWIN_BUILD_GLOBALSHORTCUTS=$(usex shortcuts)
)

ecm_src_configure
}

0 comments on commit bf898b6

Please sign in to comment.