media-libs/libva: add 2.18.0

Signed-off-by: Andrew Ammerlaan <[email protected]>

media-libs/libva/Manifest

@@ -1,2 +1,3 @@
 DIST libva-2.16.0.tar.gz 267735 BLAKE2B 59c5dc39e1c40c2f24455ec7b0588eb4898b3cab7c49ffbca997882c634ca7be6334fdb820afada8e2ebf39eb2166c95610df190d90c2a98c4fc25d25c733b32 SHA512 08a1481ac693ee9de639f2abd483e1fabfee87f9c04ead066dfce5c24cc7f1d1a29d8664707bb534ce4cc25e52086c5e4a0ecfe704ca59590ce41353fda31c2a
 DIST libva-2.17.0.tar.gz 276993 BLAKE2B 4d003f6649e4356a06438f8a88a5a549e94b12f342b1b72649b17d0aeb259ec7f26c3d1b5d21ca6cfc2b31141e01449ccc94a6bfdf2716976cbc80f63091fcfe SHA512 c9f841b4f35e732bfaa0358fe031207f011be90f95cc46acfd8c83092510cf68fe0921f28ce82402e7cce65f263eeb4d06cc17fd3c525274530a53b212f33779
+DIST libva-2.18.0.tar.gz 278493 BLAKE2B 619a1dcb9aaa71b38ec7be500adf6b526f50ae20fa76d1c5ac750229e03a2d5b82dabe334cf07c0f539c1b079829f2ec000ce6570e05e6e18fbf7415c5d5b9b3 SHA512 12e8d837604d2f354d849a8adc84281ae1ecfd2433f1b7dc8e28b5d703ada42b4a84b2b3870e8d2397b77d0d9741afe3bc04d25b4426531805aeb72defaac7ad

media-libs/libva/libva-2.18.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib optfeature
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/libva"
+else
+	SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~mips ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="opengl wayland X"
+REQUIRED_USE="opengl? ( X )"
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.60[${MULTILIB_USEDEP}]
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+		x11-libs/libxcb:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	wayland? ( dev-util/wayland-scanner )
+	virtual/pkgconfig
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/va/va_backend_glx.h
+	/usr/include/va/va_x11.h
+	/usr/include/va/va_dri2.h
+	/usr/include/va/va_dricommon.h
+	/usr/include/va/va_glx.h
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddriverdir="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		-Ddisable_drm=false
+		-Dwith_x11=$(usex X)
+		-Dwith_glx=$(usex X)
+		-Dwith_wayland=$(usex wayland)
+		-Denable_docs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature_header
+	optfeature "Older Intel GPU support up to Gen8" media-libs/libva-intel-driver
+	optfeature "Newer Intel GPU support from Gen9+" media-libs/libva-intel-media-driver
+}