dev-libs/clhpp: add 2.0.18

Signed-off-by: Marek Szuba <[email protected]>

dev-libs/clhpp/Manifest

@@ -1,2 +1,3 @@
 DIST clhpp-2.0.15.tar.gz 99826 BLAKE2B de5f6cab05d21199ffea37bbbcc5d312a4b812b602ce091d8fa22cb615060ce08454de1341881792996dd5c06378657a297505ff25ac159d85b59995e924bca5 SHA512 d24c035425c8204099e5264e61939c568e85b64e94d5ed3c58fe9430f4516495a974080a684b742f5aea1351455a0755efccd14317c20cd34885880cf1d8133b
 DIST clhpp-2.0.17.tar.gz 106799 BLAKE2B bccbbbc07e83609f49253636eb08a4da19f92c7188dad71759fa9cceaad571291c05595b8f2a7cc427ea0df658f1b7133ef0fdbbfed3ca3c29c85629b005d541 SHA512 af21fac8856a1a7d5de6ccde64dee9518740f75503808488312e226ae441e013e7340a7089f273b021a8d1e34c17dad9df51953c742eef8f8c470657a7816fe2
+DIST clhpp-2.0.18.tar.gz 106867 BLAKE2B 56f867e26ed2220566dd9f71391ccae8ea05aa6727bf5440e4bfa59948759b9251d415310aa97589baa745ae7ee6f5f7474a50a39b65d4fc1175fa7c7c1afe3d SHA512 078e935938ba1edd5ccc8f5234f344f4645ab678888f966e757eb64c3c88fa5e747ff1b931a54af656125fb8b8340c3d3a6d7e98a4adf277d6ca58b15c5c1f56

dev-libs/clhpp/clhpp-2.0.18.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27 ruby30"
+RUBY_OPTIONAL="yes"
+
+inherit cmake ruby-ng
+
+MY_PN="OpenCL-CLHPP"
+MY_PV="2022.09.23"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="Khronos OpenCL C++ bindings"
+HOMEPAGE="https://github.com/KhronosGroup/OpenCL-CLHPP/"
+SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/refs/tags/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Khronos-CLHPP"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# Tests require CMock (NOT cmocka), which is currently unpackaged
+RESTRICT="test"
+
+RDEPEND="virtual/opencl"
+DEPEND="${RDEPEND}
+	>=dev-util/opencl-headers-${MY_PV}"
+BDEPEND="test? ( $(ruby_implementations_depend) )"
+
+S="${WORKDIR}"/${MY_P}
+
+pkg_setup() {
+	use test && ruby-ng_pkg_setup
+}
+
+src_unpack() {
+	# suppress ruby-ng export
+	default
+}
+
+src_prepare() {
+	# suppress ruby-ng export
+	cmake_src_prepare
+}
+
+src_compile() {
+	# suppress ruby-ng export
+	cmake_src_compile
+}
+
+src_install() {
+	# suppress ruby-ng export
+	cmake_src_install
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCS=OFF
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_TESTING=$(usex test)
+	)
+	cmake_src_configure
+}