app-crypt/acme-sh: add 3.0.8

Signed-off-by: Conrad Kostecki <[email protected]>

app-crypt/acme-sh/Manifest

@@ -1 +1,2 @@
 DIST acme.sh-3.0.7.tar.gz 284269 BLAKE2B 2e3d81446772049660d3a7b8005b82a890238d33ef16211b304ecd9b996063de9e788095ff958422f90d2e20615f84943d6085959ac2f27d6ad51a8eeffb2800 SHA512 83d080b461662bf2c5cfa9cb51aaf41d7f873f54908e2e5f94d7e3fe8e3f6953d73aafb66adc97455aa958f37c72ef77ba475c7d7cbb3ca3c5bbffb4937c4bae
+DIST acme.sh-3.0.8.tar.gz 296583 BLAKE2B becc2402edb9cfb867662b91dd0925c151b21cc56d9c956513678ede22cab1ddcb0cdf424131d301f349a10245a5566fcfcf87f16b927b5c7fb9211e9f070de5 SHA512 e18e75557a4b10a71a726bbef6383c7bc9276b7dcdcc80756da3136b2d9f819e787ef477fec326d05d96dbc90c114fb2a418889aaac996717a6c456cd131d30b

app-crypt/acme-sh/acme-sh-3.0.8.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN/-/.}"
+MY_P="${MY_PN}-${PV}"
+
+inherit optfeature
+
+DESCRIPTION="A pure Unix shell script implementing ACME client protocol"
+HOMEPAGE="https://github.com/acmesh-official/acme.sh"
+SRC_URI="https://github.com/acmesh-official/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+IUSE="selinux"
+
+RDEPEND="
+	dev-libs/openssl:0
+	net-misc/curl
+	net-misc/socat
+	selinux? ( sec-policy/selinux-certbot )
+"
+
+src_install() {
+	newdoc deploy/README.md README-deploy.md
+	newdoc dnsapi/README.md README-dnsapi.md
+	rm {deploy,dnsapi}/README.md || die
+	einstalldocs
+
+	exeinto /usr/share/acme.sh
+	doexe acme.sh
+
+	insinto /usr/share/acme.sh
+	doins -r deploy dnsapi notify
+
+	keepdir /etc/acme-sh
+	doenvd "${FILESDIR}"/99acme-sh
+
+	insinto /etc/bash/bashrc.d
+	doins "${FILESDIR}"/acme.sh
+
+	dosym ../share/acme.sh/acme.sh usr/bin/acme.sh
+}
+
+pkg_postinst() {
+	optfeature_header "For webserver mode, install a supported web server:"
+	optfeature "using apache2 webserver mode" www-servers/apache
+	optfeature "using nginx webserver mode" www-servers/nginx
+}