app-cdr/dolphin-plugins-mountiso: 22.04.1 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

app-cdr/dolphin-plugins-mountiso/Manifest

@@ -1,2 +1,3 @@
 DIST dolphin-plugins-21.12.3.tar.xz 254696 BLAKE2B e669a8acbf8b5559a602dd3ae646e2384b89a672bb0ed42d2f094b75a1eaefd6994644daaa70d17f9baba8ea491cef632090050b93e0f5e0b50f203a6166338e SHA512 3dad72b6e0283a8c825aded82e9d15bc5e03303bbfc6dd8f1e6af2cb3892ec9b04a3c97f01246e20abe6d86e5a91fa1c4f8fff48ed24186a3780009a78298d23
 DIST dolphin-plugins-22.04.0.tar.xz 256164 BLAKE2B 8980f3d7687b456edc81d69027c66f1e7801fa5876ef605a021caecae02b7b30596b1b9bdd8c0de2b5c6c98393eafb75bedc6f0d411d144fa430619778ff7f97 SHA512 3c7dcc1404cbfbb0a4805eb1116dae53b03fa1b49ee483b09009f32035d0939fc8bedd65866765e94d5294185f42bda4b6aaba6486c52ea2a524e5678e6b4c28
+DIST dolphin-plugins-22.04.1.tar.xz 256196 BLAKE2B ae55ea9210f6a8b2ca33c6542af5cdc33b129b611ea3b7b20e98d96af9af99db954ec7560dae83a78be6857ca7c051d6a80d2e4201e5179d2918d98d82706a30 SHA512 0833311429857a6aeccb19736ac2d49e8b4e0e9f9d393b2835b33f8f17032382d07fbcf61dd03d37dccebcaea1b3a542c5478f24dd47b52749bd1259461caa2f

app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-22.04.1.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_GEAR="true"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.92.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.3
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}