dev-scheme/guile-git: bump up to 0.4.0

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <[email protected]>

dev-scheme/guile-git/Manifest

@@ -1 +1,2 @@
 DIST guile-git-0.3.0.tar.gz 275273 BLAKE2B 75c7e9b89446676adfa5e81c6cfeac9df19d77d1565450fdf892c01f9ef472dafe0ee7f8c8ff888421457d8e260e6f8e02a6e846952cbbff69ef4d75a467787c SHA512 98af9106c0b5d0f01c6d9550705c58116b8a38acb3c329e08822b8b81717c7c0147cfd74314e693c803e17b476af7b2f80ed2422652bbebfcc14271b654e839d
+DIST guile-git-0.4.0.tar.gz 295398 BLAKE2B 6fac958282d8e7e7162ca942a7c524c02846917f7e2ee2c7b10f72437193dfd0e33813ec9d101371b95c09e10b7b04d3c5a7f784c95cf39187624f83b2affb5b SHA512 59a4d3bd93f8e074d3df91ed190378f9e65c191945eb78f3eac894130cac8f068841a8a9e5c00131b19d99d5e483d07c4c9b0479dddf5885b2c2da28763f2de8

dev-scheme/guile-git/guile-git-0.4.0.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Guile bindings of git"
+HOMEPAGE="https://gitlab.com/guile-git/guile-git"
+SRC_URI="https://gitlab.com/guile-git/guile-git/uploads/2600bb0dfdfb00bfbe46811dccad51d8/guile-git-${PV}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# older libgit seems to be incompatible with guile-git bindings
+# https://github.com/trofi/nix-guix-gentoo/issues/7
+RDEPEND="
+	>=dev-scheme/guile-2.0.11:=
+	dev-scheme/bytestructures
+	>=dev-libs/libgit2-1:=
+"
+DEPEND="${RDEPEND}"
+
+RESTRICT=test # Tets suite needs a fix: https://gitlab.com/guile-git/guile-git/issues/18
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_FLAGS_IGNORED='.*[.]go'
+
+src_prepare() {
+	default
+
+	# guile is trying to avoid recompilation by checking if file
+	#     /usr/lib64/guile/2.2/site-ccache/<foo>
+	# is newer than
+	#     <foo>
+	# In case it is instead of using <foo> guile
+	# loads system one (from potentially older version of package).
+	# To work it around we bump last modification timestamp of
+	# '*.scm' files.
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+}
+
+src_test() {
+	emake check VERBOSE=1
+}