app-arch/zstd: Bump

Package-Manager: Portage-2.3.63, Repoman-2.3.12
Signed-off-by: Patrick Lauer <[email protected]>

app-arch/zstd/Manifest

@@ -5,3 +5,4 @@ DIST zstd-1.3.4.tar.gz 2059958 BLAKE2B b1d332a35066fb00e32c6dccebd5ad1065bcc3c7d
 DIST zstd-1.3.6.tar.gz 1823482 BLAKE2B 24f3ace8b16364abcc010d26827d482fac30ebaa48ada9e3e72c25bfc3447691d4caeb40cad60fb8f2a4a6bd3512736e74c0d2e26efc94f3f6a24c9a38d339b1 SHA512 2a0144cab77954f00a8e876747be9c8b9773cde7c22ad9bfea4e44e290beabee9b530a7961ef79d0f21893d48311217369a268d4c4920fa5f840c70a852fe01f
 DIST zstd-1.3.7.tar.gz 1825458 BLAKE2B 2a689289ec70fd510575aecebf88ad763bd150e578d70d9fbb1678cba314c90a60339697232a5515990505e3c889aac92c3c2c4c3fc48e0d434b4dfd6cac9df1 SHA512 b7a432b13e237ac1490cd82b87727f6a4385d5ea7b89f566dea61a3993e17909c03288f727326ada326e36eb47ea5f9eab67c097808ee42f52cc800a7f7e1738
 DIST zstd-1.3.8.tar.gz 1875233 BLAKE2B c9775b0e33e61d2c064df60a266246f6b9b65b70ba2cc529633cf700b5dcac795e13ec0e20bd51bdd02ee5fddbc7f2fc030902ee37a5a433c2d7828c285b3c23 SHA512 834f7b6477c1e7d70f71105ea52be15c33866b48b93b7a3c6dff4f10c761e5ad35f3903899516317690a4b768051f6eedf7c030292f57cea5613d4017fab9466
+DIST zstd-1.4.0.tar.gz 1898741 BLAKE2B 1b92a055712bb47c3d56c51f3ddddeaba00f9b746f7e47a2fa1a0afdf9798ff90f0ec734880a5d03644d47deb0e55f75c2cd3cbdab1a146dba5f49d4efeb2ae0 SHA512 8614934e25eb1e82b554c483bc9d2d055f51344697295e83b22a8d726321b12068cfa7f7d2a9fe28a2de7c9edda59733826277efc7046e13674d6f7f02af5671

app-arch/zstd/zstd-1.4.0.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal toolchain-funcs
+
+DESCRIPTION="zstd fast compression library"
+HOMEPAGE="https://facebook.github.io/zstd/"
+SRC_URI="https://github.com/facebook/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="lz4 static-libs"
+
+RDEPEND="app-arch/xz-utils
+	lz4? ( app-arch/lz4 )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_compile() {
+	emake -C lib \
+		CC="$(tc-getCC)" \
+		AR="$(tc-getAR)" \
+		PREFIX="${EPREFIX}/usr" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		libzstd libzstd.a libzstd.pc
+
+	if multilib_is_native_abi ; then
+		emake \
+			CC="$(tc-getCC)" \
+			AR="$(tc-getAR)" \
+			HAVE_LZ4=$(usex lz4 1 0) \
+			PREFIX="${EPREFIX}/usr" \
+			LIBDIR="${EPREFIX}/usr/$(get_libdir)" zstd
+
+		emake -C contrib/pzstd \
+			CC="$(tc-getCC)" \
+			CXX="$(tc-getCXX)" \
+			AR="$(tc-getAR)" \
+			PREFIX="${EPREFIX}/usr" \
+			LIBDIR="${EPREFIX}/usr/$(get_libdir)"
+	fi
+}
+
+multilib_src_install() {
+	emake -C lib \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}/usr" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" install
+
+	if multilib_is_native_abi ; then
+		emake -C programs \
+			DESTDIR="${D}" \
+			PREFIX="${EPREFIX}/usr" \
+			LIBDIR="${EPREFIX}/usr/$(get_libdir)" install
+
+		emake -C contrib/pzstd \
+			DESTDIR="${D}" \
+			PREFIX="${EPREFIX}/usr" \
+			LIBDIR="${EPREFIX}/usr/$(get_libdir)" install
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if ! use static-libs; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+}