dev-vcs/svn2git: EAPI 8 + UnusedInherits

Signed-off-by: Sebastian Pipping <[email protected]>

dev-vcs/svn2git/svn2git-1.0.18-r1.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qmake-utils
+[[ "${PV}" == "9999" ]] && inherit git-r3
+
+DESCRIPTION="Tool for one-time conversion from svn to git"
+HOMEPAGE="https://github.com/svn-all-fast-export/svn2git"
+if [[ "${PV}" == "9999" ]]; then
+ EGIT_REPO_URI="https://github.com/svn-all-fast-export/svn2git.git"
+else
+ SRC_URI="https://github.com/svn-all-fast-export/svn2git/archive/${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE=""
+# KEYWORDS way up
+
+DEPEND="
+ dev-qt/qtcore:5
+ dev-vcs/subversion"
+RDEPEND="${DEPEND}
+ dev-vcs/git"
+
+DOCS=( README.md )
+
+src_configure() {
+ local qmake_args=(
+ APR_INCLUDE=/usr/include/apr-1
+ PREFIX=/usr
+ SVN_INCLUDE=/usr/include/subversion-1
+ VERSION=${PV}
+ )
+ eqmake5 "${qmake_args[@]}" fast-export2.pro
+}
+
+src_install() {
+ einstalldocs
+ insinto /usr/share/${PN}/samples
+ doins samples/*.rules
+ dobin svn-all-fast-export
+ dosym svn-all-fast-export /usr/bin/svn2git
+}

dev-vcs/svn2git/svn2git-9999.ebuild

@@ -1,9 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit desktop qmake-utils
+inherit qmake-utils
 [[ "${PV}" == "9999" ]] && inherit git-r3
 
 DESCRIPTION="Tool for one-time conversion from svn to git"