dev-python/graph-tool: add 2.71

Signed-off-by: David Seifert <[email protected]>

dev-python/graph-tool/Manifest

@@ -1 +1,2 @@
 DIST graph-tool-2.58.tar.xz 14949712 BLAKE2B f7edfc112e737aad09317b2a754eefa8fad0135d580766b24ef5eb08d9e748a65a7372d95b9b00ffd891a2fe033f7ca29348b700e145361c48c95fe31a9f1500 SHA512 bfb604073c71b1f4a605008e5bfa6414370bc5c14e1b501e1821c1d363370e2f1f7c6dcedabf67723286cac07def1442c24577308458a75c4fc70aee69bf22ee
+DIST graph-tool-2.71.tar.xz 14997876 BLAKE2B c23b4729065ebba43ba3501bca63980a40354e2ff6727ea3b663c60521cdf571ab794eb83f9cfb56909d92e3be90ac5d94c7dcd7f6639cb2c2fb9ee5c675697f SHA512 caedba222e499b81d93d51097c526a8a64dd1f3b91141012c67ffe40532f6168294e430887484522f75709828d280f95cc75bc400a886e71bf73d64efd9b7833

dev-python/graph-tool/graph-tool-2.71.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	cairo? (
+		dev-cpp/cairomm:0
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		x11-libs/cairo[X]
+	)"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/0001-Fix-compilation-with-boost-1.83-and-boost-1.76.patch # backport
+)
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	my_configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir my_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir emake
+}
+
+src_install() {
+	my_python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir my_python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}