app-editors/hteditor: bump up to 2.1.1_pre20161206

It's a snapshort of latest code available in upstream repository.

Reported-by: Agostino Sarubbo
Closes: https://bugs.gentoo.org/729252
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Sergei Trofimovich <[email protected]>

app-editors/hteditor/Manifest

@@ -1 +1,2 @@
 DIST ht-2.1.0.tar.bz2 884139 BLAKE2B c979563cbfc4df7e14f587b250fbf099d9f4683afddb3afc88693284c378c45466dfa3c47555fc69e83e2972cfabab63f3cdd42fd85602842854372131e4063d SHA512 6b5fc5fcbc63b9b7c85721158e044e4578ebfdc38618c760c0e6de06a276bccd3a960ab8bed172de788934515ad94d86349c4abd3228da66b1601deaaa2ce410
+DIST ht-2.1.1_pre20161206.tar.gz 1082309 BLAKE2B 4fb00b0aa6115da3b561436f9f9905c48d93d6768bcf207931bb46840727c85fb5c9a1afda8ed805f71e9ce242161a2b95e26add02ff5aedc407df7f11c6ddec SHA512 33d681ee8c978568dd0d187d6846994362625d000c316baab10c237175fa6a47dc0e7b61cfd503c4dfad8a01d27af7fc87cbf20109087e1d9280048c898fa621

app-editors/hteditor/hteditor-2.1.1_pre20161206.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P=${P/editor}
+
+DESCRIPTION="A file viewer, editor and analyzer for text, binary, and executable files"
+HOMEPAGE="http://hte.sourceforge.net/ https://github.com/sebastianbiallas/ht/"
+#SRC_URI="mirror://sourceforge/hte/${MY_P}.tar.bz2"
+# tarball is done as: 'make dist' and then rename to mention latest commt
+SRC_URI="https://dev.gentoo.org/~slyfox/distfiles/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="X"
+
+RDEPEND="sys-libs/ncurses:0=
+	X? ( x11-libs/libX11 )
+	>=dev-libs/lzo-2"
+DEPEND="${RDEPEND}
+	virtual/yacc
+	sys-devel/flex"
+
+DOCS=( AUTHORS ChangeLog KNOWNBUGS README TODO )
+
+S=${WORKDIR}/${MY_P/_pre*}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.1.0-tinfo.patch
+	"${FILESDIR}"/${PN}-2.1.0-gcc-6-uchar.patch
+)
+
+src_configure() {
+	econf \
+		$(use_enable X x11-textmode) \
+		--enable-maintainermode
+}
+
+src_install() {
+	#For prefix
+	chmod u+x "${S}/install-sh"
+
+	local HTML_DOCS="doc/*.html"
+	doinfo doc/*.info
+
+	default
+}