gui-apps/waypipe: add 0.9.0

Closes: https://bugs.gentoo.org/929605
Signed-off-by: Arthur Zamarin <[email protected]>

gui-apps/waypipe/Manifest

@@ -1,2 +1,3 @@
 DIST waypipe-0.8.0.tar.gz 217533 BLAKE2B a2aebb9939acafae3eb693aa8fe344ab775e8d3e9a071e7291ab15a0f9869b681156b5730e42c04401648a32ad2a67d7a3bf95ff5f38e909e9309e00b1c69381 SHA512 853d36a9779e2fcb5ac7bcca6575d456685beadd8d918ec430a57b8359867849bdcb5d9c1edcd19eb8505f06a7758e8f53ba5354daa05f99491d5a45c330eeb2
 DIST waypipe-v0.8.6.tar.bz2 189836 BLAKE2B 4023ddb325982d5cb189bafb9c4bf87f1ccd692c423371b05d273ab2d8ceeeacace256400e5755e89670407746f25ff4499643d3fb722053e5958547ac15600f SHA512 d02afa15e363009820e7e7ad75e8f294a58b42ec74f8a2cd310fc3c65a252b71524a89fb95e3e105cec8d6802fb30470c6842ae69d7c16d687edde96d4ff1263
+DIST waypipe-v0.9.0.tar.bz2 193493 BLAKE2B 891b1015951459faf15c181c35499558458fd69c63695f4b6be67e686c8ba7806f0193ed0fc4500b370345b570536b6fdbb3c01f2fe861e87e00b1d4db7c05d7 SHA512 c37b630f4659ccc52d2a85a749971d552d5d535fc33e30aea1c2d22b057aaf3cf2756d6347cc89e3068ce59a14e871e7ffae9016608803549d0e7b1b6a0bd1cf

gui-apps/waypipe/waypipe-0.9.0.ebuild

@@ -0,0 +1,69 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit meson python-any-r1
+
+DESCRIPTION="Transparent network proxy for Wayland compositors"
+HOMEPAGE="https://gitlab.freedesktop.org/mstoeckl/waypipe"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe"
+else
+	SRC_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	S="${WORKDIR}"/${PN}-v${PV}
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+WAYPIPE_FLAG_MAP_X86=( avx2:with_avx2 avx512f:with_avx512f sse3:with_sse3 )
+WAYPIPE_FLAG_MAP_ARM=( neon:with_neon_opts )
+WAYPIPE_FLAG_MAP=(
+	"${WAYPIPE_FLAG_MAP_X86[@]/#/cpu_flags_x86_}"
+	"${WAYPIPE_FLAG_MAP_ARM[@]/#/cpu_flags_arm_}"
+)
+
+IUSE="dmabuf ffmpeg lz4 systemtap test vaapi zstd ${WAYPIPE_FLAG_MAP[@]%:*}"
+REQUIRED_USE="vaapi? ( ffmpeg )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dmabuf? (
+		media-libs/mesa[gbm(+),vaapi?,wayland]
+		x11-libs/libdrm
+	)
+	ffmpeg? ( media-video/ffmpeg[x264,vaapi?] )
+	lz4? ( app-arch/lz4 )
+	systemtap? ( dev-debug/systemtap )
+	vaapi? ( media-libs/libva[drm(+),wayland] )
+	zstd? ( app-arch/zstd )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	app-text/scdoc
+	virtual/pkgconfig
+	test? ( dev-libs/weston[examples,headless,remoting,screen-sharing,wayland-compositor] )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=enabled
+		$(meson_use systemtap with_systemtap)
+		$(meson_feature dmabuf with_dmabuf)
+		$(meson_feature ffmpeg with_video)
+		$(meson_feature lz4 with_lz4)
+		$(meson_feature vaapi with_vaapi)
+		$(meson_feature zstd with_zstd)
+	)
+	local fl
+	for fl in "${WAYPIPE_FLAG_MAP[@]}"; do
+		emesonargs+=( $(meson_use "${fl%:*}" "${fl#*:}") )
+	done
+	meson_src_configure
+}