media-video/nvidia-settings: Version Bump

Package-Manager: portage-2.2.26
Signed-off-by: Justin Lecher <[email protected]>

media-video/nvidia-settings/Manifest

@@ -1,2 +1,3 @@
 DIST nvidia-settings-340.58.tar.bz2 1549850 SHA256 21cd29fea50e62766d1985c84f6d6de8efa911e32abcbff8e7ccf0e43ebe25c0 SHA512 4c581a940c99fac28564ab6154f47cae496ebfda6339b7f10c5decf8fea52b6c12e5b63dfcf78f8365909e49539560a50338edb17117881b6a03c196bd51836c WHIRLPOOL b486032339c4f8c4767239e3a4b001667bceb2c3ef5f3e94f08d1c54c60a958e1c76456415769ce9ff0503b6eb3d903aa89599a0234e08447c33671c598e66c8
 DIST nvidia-settings-355.11.tar.bz2 1570699 SHA256 999ebc9e12ca1a6b6195d439f08aac0b9420f8117e42cac62dccd2872dabb74b SHA512 7565e3d809c5f27ec9ca092a6369cf89ca7571e0cb1b1285c50192cc1cc763e95316d9c71d06ed2333077b97946318e825c6d672f48549b58bd41faa673fb49c WHIRLPOOL 700a0c70fe63d4379d4ccb9dc7aa4350fbdc8b0c67d0a2d13c117d06b81fdf3fc7f1a690f9293b20f03a1876494d63ad5d4ec2536573f726d23cdbfa49c36c4e
+DIST nvidia-settings-358.16.tar.bz2 1571104 SHA256 8cd78df738a824e282771755ae9a41d5b194b15f9df96b9fd23fcf3005967d35 SHA512 0438aa2599e98f68a04c9f663f4ef9b05092df512fbca40ad0fe17e25ca4d940d02cc55e9fd44a2551950a2a30782d1e48553c4bebd071bfff280869a6dde556 WHIRLPOOL 60b7e9abba3163ac877a3a9d944cf72352e28d2fd1a3af0996d3b7d40ef48be7f057c1063f9ca61c693cbf1bff57be61704f13d941220bf74a8049954f87154d

media-video/nvidia-settings/nvidia-settings-355.11.ebuild

@@ -15,7 +15,8 @@ SLOT="0"
 KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
 IUSE="examples gtk3"
 
-COMMON_DEPEND="x11-libs/gtk+:2
+COMMON_DEPEND="
+	x11-libs/gtk+:2
 	gtk3? ( x11-libs/gtk+:3 )
 	x11-libs/libX11
 	x11-libs/libXext

media-video/nvidia-settings/nvidia-settings-358.16.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="NVIDIA Linux X11 Settings Utility"
+HOMEPAGE="http://www.nvidia.com/"
+SRC_URI="ftp://download.nvidia.com/XFree86/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
+IUSE="examples gtk3"
+
+COMMON_DEPEND="
+	x11-libs/gtk+:2
+	gtk3? ( x11-libs/gtk+:3 )
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXxf86vm
+	x11-libs/gdk-pixbuf[X]
+	media-libs/mesa
+	x11-libs/pango[X]
+	x11-libs/libXv
+	x11-libs/libXrandr
+	dev-libs/glib:2
+	dev-libs/jansson
+	x11-libs/cairo
+	>=x11-libs/libvdpau-1.0"
+
+RDEPEND="${COMMON_DEPEND}
+	x11-drivers/nvidia-drivers:0/358"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	x11-proto/xproto"
+
+src_compile() {
+	einfo "Building libXNVCtrl..."
+	emake -C src/ \
+		CC="$(tc-getCC)" \
+		AR="$(tc-getAR)" \
+		RANLIB="$(tc-getRANLIB)" \
+		build-xnvctrl
+
+	einfo "Building nvidia-settings..."
+	emake -C src/ \
+		CC="$(tc-getCC)" \
+		LD="$(tc-getLD)" \
+		STRIP_CMD="$(type -P true)" \
+		NV_VERBOSE=1 \
+		NV_USE_BUNDLED_LIBJANSSON=0 \
+		NVML_AVAILABLE=0 \
+		GTK3_AVAILABLE=$(usex gtk3 1 0)
+}
+
+src_install() {
+	emake -C src/ DESTDIR="${D}" PREFIX=/usr NV_USE_BUNDLED_LIBJANSSON=0 GTK3_AVAILABLE=$(usex gtk3 1 0) install
+
+	insinto /usr/$(get_libdir)
+	doins src/libXNVCtrl/libXNVCtrl.a
+
+	insinto /usr/include/NVCtrl
+	doins src/libXNVCtrl/*.h
+
+#	doicon doc/${PN}.png # Installed through nvidia-drivers
+	make_desktop_entry ${PN} "NVIDIA X Server Settings" ${PN} Settings
+
+	# bug 412569 - Installed through nvidia-drivers
+#	rm -rf "${D}"/usr/share/man
+
+	dodoc doc/*.txt
+
+	if use examples; then
+		docinto examples/
+		dodoc samples/*.c
+		dodoc samples/README
+	fi
+}