app-arch/pixz: version bump to 1.0.6 (bug #572728)

app-arch/pixz/Manifest

@@ -1 +1,2 @@
 DIST pixz-1.0.3.tar.gz 27105 SHA256 49f44520b411315ec4b02891eb77ba6060bdfd77ab5112e9c3e21de581c3384d SHA512 e33e038fc760a51b5bbc52c4faca2b165a5e4546438cd1bf9b41b91d6c8aabad43be367750ac1e7a7007c6d2544ce6dd4662fa60c99c763d96d918eeed002fa7 WHIRLPOOL 29ba24955280051d2d7562aca0b908c1228d0345beb7a6b1e330714ac8c39f6e86a87d60581c91a578950a9dfabbc96c59f64e8afecd2100499c64d4007f5477
+DIST pixz-1.0.6.tar.gz 27603 SHA256 ebde85148e927ed96abaeb9ab2166435c78d31e7c6b2847e8c8d6249b17f1b60 SHA512 432b4714501e4de53d5e4a9d91244cdf9b19cd3ef568d750e630cca16c91644073da6ff2ad676004e70a0a09b18dfdb9d6592420da47f0da3de64ec0757da2f7 WHIRLPOOL c796de23e0a0d78e28a03597202aa9730a2d57fa11942f705b726c48a1b42d9c7580c0efb11133fad7e461b937d1af6760f648fbf6d9a0196486753104ad161e

app-arch/pixz/pixz-1.0.6.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs flag-o-matic autotools
+
+DESCRIPTION="Parallel Indexed XZ compressor"
+HOMEPAGE="https://github.com/vasi/pixz"
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="static"
+
+LIB_DEPEND=">=app-arch/libarchive-2.8:=[static-libs(+)]
+	>=app-arch/xz-utils-5[static-libs(+)]"
+RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
+DEPEND="${RDEPEND}
+	static? ( ${LIB_DEPEND} )
+	app-text/asciidoc"
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/vasi/${PN}.git"
+	inherit git-r3
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/vasi/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	append-flags -std=gnu99
+	econf
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" OPT=""
+}
+
+src_install() {
+	dobin src/pixz
+	doman src/pixz.1
+	dodoc NEWS README.md TODO
+}

app-arch/pixz/pixz-9999.ebuild

@@ -1,8 +1,8 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
+EAPI=6
 
 inherit toolchain-funcs flag-o-matic autotools
 
@@ -29,6 +29,7 @@ else
 fi
 
 src_prepare() {
+	default
 	eautoreconf
 }
 
@@ -45,5 +46,5 @@ src_compile() {
 src_install() {
 	dobin src/pixz
 	doman src/pixz.1
-	dodoc README.md TODO
+	dodoc NEWS README.md TODO
 }