media-sound/mpd: Version bump (bug #590074 by Perfect Gentleman).

Package-Manager: portage-2.3.0

media-sound/mpd/Manifest

@@ -3,3 +3,4 @@ DIST mpd-0.19.11.tar.xz 703064 SHA256 7a5c66aa5af97a5b7af3dc49e3d2594071dafd62a1
 DIST mpd-0.19.12.tar.xz 703340 SHA256 7b6fe6c7ce72f5f80a276d680072b524ecb395e546e252b8f3a0756377e1e875 SHA512 a608c99096d0ec9158cba5615be344a47d76c5be830ba34445e330f141aaa828784772d772df20d71d4c65e78ea5dfe9fb59ea4f4f823fa112a00517963a6e7e WHIRLPOOL ab1c0ba6a92f5582c774b36f10d2433ccd4b796cb38d35ff0accdf0d29b95268f13f462446b72df52f2b8fb4a7b5e297fb37d1303b38412c4e73f0769dbbf7bd
 DIST mpd-0.19.14.tar.xz 703388 SHA256 2fd23805132e5002a4d24930001a7c7d3aaf55e3bd0cd71af5385895160e99e7 SHA512 378c31033fd846c4a025c3e45ea61fd79378421371e1b4aa2ac3cf9f10d5c47d930bc6b052055f8f2c70fa98c6d471be73e3e6d6ede568057f7279753b017f40 WHIRLPOOL 2c095e75031daa86c9d49999a52ca41eb4233e2c4f1c3dc2e97cba734b083b28d91450d812a3b61e71ca3b350588332efb122451d1dfbb980d2c93458fb59e5e
 DIST mpd-0.19.15.tar.xz 704000 SHA256 0cb9a223894b038ce966ce6d651d9b3ea3bdc7d7b9bec8d1e9e7e091cbc29b8b SHA512 19cf80dcaadbc164e3f1b0989266b16edc232a9f3549718ccaabf8849ef5821ac8b5416ccc05a58f23bb788a06007b12136fb8b17013311080b72e67a4adc8a5 WHIRLPOOL 6205261e6b9f3eab8aacba8cfd75d4de4e4a097419ad2d69954a8eb3544701068857c7bb84c09fc1cfa9022e13542832362ecd7711666740fafc79b0b307b2e5
+DIST mpd-0.19.18.tar.xz 707252 SHA256 764c991c54980cb97e876e3f65d63410c0c561b7be996b832e058053e005ed47 SHA512 9674a8e9d2086373c59d3ce66bddb70e914f863dc384a283071ac8003ddae304d7020fc654db72c6f4aa30cb18e67dadd3d0a62069538a7ec666c3076e7bc1f8 WHIRLPOOL cbf6f66c61d7c5b690e4175666eb65272c2eeb9e558abe14f6dea008609dfacd5d027106fb412121cbc4ffe7304209f3793505148727e18c4e5c03bd76e1db79

media-sound/mpd/mpd-0.19.18.ebuild

@@ -0,0 +1,257 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic linux-info multilib systemd user
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="http://www.musicpd.org"
+SRC_URI="http://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~x64-macos"
+IUSE="adplug +alsa ao audiofile bzip2 cdio +curl debug +eventfd expat faad
+	+fifo +ffmpeg flac fluidsynth +glib gme +icu +id3tag +inotify +ipv6 jack
+	lame mms libav libmpdclient libsamplerate libsoxr +mad mikmod modplug
+	mpg123 musepack +network nfs ogg openal opus oss pipe pulseaudio recorder
+	samba selinux sid +signalfd sndfile soundcloud sqlite systemd tcpd twolame
+	unicode upnp vorbis wavpack wildmidi zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
+DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack ogg flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	ao? ( glib )
+	gme? ( glib )
+	jack? ( glib )
+	network? ( || ( ${ENCODER_PLUGINS} )
+		glib )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	sid? ( glib )
+	soundcloud? ( glib )
+	sqlite? ( glib )
+	opus? ( ogg )
+	upnp? ( expat )
+	vorbis? ( glib )
+	wavpack? ( glib )"
+
+CDEPEND="!<sys-cluster/mpich2-1.4_rc2
+	adplug? ( media-libs/adplug )
+	alsa? ( media-sound/alsa-utils
+		media-libs/alsa-lib )
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio-paranoia )
+	curl? ( net-misc/curl )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	glib? ( dev-libs/glib:2 )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? ( dev-libs/icu:= )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	musepack? ( media-sound/musepack-tools )
+	network? ( >=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
+	nfs? ( net-fs/libnfs )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( || ( <net-fs/samba-4.0.25[smbclient] >=net-fs/samba-4.0.25 ) )
+	sid? ( media-libs/libsidplay:2 )
+	sndfile? ( media-libs/libsndfile )
+	soundcloud? ( >=dev-libs/yajl-2 )
+	libsoxr? ( media-libs/soxr )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	upnp? ( net-libs/libupnp )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${CDEPEND}
+	dev-libs/boost
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-mpd )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.18.conf.patch
+	"${FILESDIR}"/${PN}-0.9.15-systemd.patch # bug 584742
+)
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+	if use eventfd || use signalfd || use inotify; then
+		linux-info_pkg_setup
+	fi
+
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make
+		sure that MPD's pid_file is _set_."
+}
+
+src_prepare() {
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local mpdconf="--enable-database --disable-roar --disable-documentation
+		--enable-dsd --enable-largefile --disable-osx --disable-shine-encoder
+		--disable-solaris-output --enable-tcp --enable-un --disable-werror
+		--docdir=${EPREFIX}/usr/share/doc/${PF}"
+
+	if use network; then
+		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output $(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)"
+	else
+		mpdconf+=" --disable-shout --disable-vorbis-encoder
+			--disable-httpd-output --disable-lame-encoder
+			--disable-twolame-encoder --disable-wave-encoder"
+	fi
+
+	if use samba || use upnp; then
+		mpdconf+=" --enable-neighbor-plugins"
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	econf \
+		$(use_enable eventfd)		\
+		$(use_enable signalfd)		\
+		$(use_enable libmpdclient)	\
+		$(use_enable expat)			\
+		$(use_enable upnp)			\
+		$(use_enable adplug)		\
+		$(use_enable alsa)			\
+		$(use_enable ao)			\
+		$(use_enable audiofile)		\
+		$(use_enable zlib)			\
+		$(use_enable bzip2)			\
+		$(use_enable cdio cdio-paranoia) \
+		$(use_enable curl)			\
+		$(use_enable samba smbclient) \
+		$(use_enable nfs)			\
+		$(use_enable debug)			\
+		$(use_enable ffmpeg)		\
+		$(use_enable fifo)			\
+		$(use_enable flac)			\
+		$(use_enable fluidsynth)	\
+		$(use_enable gme)			\
+		$(use_enable id3tag id3)	\
+		$(use_enable inotify)		\
+		$(use_enable ipv6)			\
+		$(use_enable cdio iso9660)	\
+		$(use_enable jack)			\
+		$(use_enable soundcloud)	\
+		$(use_enable tcpd libwrap)	\
+		$(use_enable libsamplerate lsr) \
+		$(use_enable libsoxr soxr)	\
+		$(use_enable mad)			\
+		$(use_enable mikmod)		\
+		$(use_enable mms)			\
+		$(use_enable modplug)		\
+		$(use_enable musepack mpc)	\
+		$(use_enable mpg123)		\
+		$(use_enable openal)		\
+		$(use_enable opus)			\
+		$(use_enable oss)			\
+		$(use_enable pipe pipe-output) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable recorder recorder-output) \
+		$(use_enable sid sidplay)	\
+		$(use_enable sndfile sndfile) \
+		$(use_enable sqlite)		\
+		$(use_enable systemd) \
+		$(use_enable vorbis)		\
+		$(use_enable wavpack)		\
+		$(use_enable wildmidi)		\
+		$(use_enable zip zzip)		\
+		$(use_enable icu)			\
+		$(use_enable glib)			\
+		$(use_enable faad aac)		\
+		$(use_with zeroconf zeroconf avahi) \
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir) \
+		${mpdconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/${PN}2.init ${PN}
+
+	systemd_newuserunit systemd/${PN}.service ${PN}.service
+	sed -i '/WantedBy=/c WantedBy=default.target' \
+		"${ED}"/usr/lib/systemd/user/mpd.service || die "sed failed"
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${ED}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotate ${PN}
+
+	use prefix || diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+}
+
+pkg_postinst() {
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}