dev-java/openjdk-jre-bin: bump to 8.212_p03

Package-Manager: Portage-2.3.63, Repoman-2.3.12
Signed-off-by: Georgy Yakovlev <[email protected]>

dev-java/openjdk-jre-bin/Manifest

@@ -1,2 +1,3 @@
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.2_9.tar.gz 41525058 BLAKE2B da456e8415ef45d07968c12082f2351910284b47bac92a952d4962fbc4c63cb2fa006696b6b175e0d1073b1fca76cca61460465d0959afe80d2f5ce9006d9350 SHA512 96b527be34c49e6351bed0d000153c1bc9491cf89f8a7f90190feccd2984cce1e3d18747e108d476c4417f15947d436f20cd34fe88f8126edecf4a789d725b0a
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u202b08.tar.gz 40856726 BLAKE2B d9d4599989a0232bcc145aaf58b20dbfcedbe33adb2b3ee65b7e726dea350210f66eb81b321268a29d3234244c517642cfe908531242afb220509666e02c0617 SHA512 f9bb03cd0876f6b3b36d8ba821a14648b5ac2ec6dc6eefb95dc333aae77b55c940153cdd1715b21feaf7d7f2148bf8c272777c8afab911965e514f9792287962
+DIST OpenJDK8U-jre_x64_linux_hotspot_8u212b03.tar.gz 40871242 BLAKE2B 8a6eee7f7465cbccc575e44ab08d6a3d2cedc32954475ea71064a4b6d4379927a795225fed7394922bdaa2a425efb6966d6a0126a55a0fa0e68dc0eeb7a6e935 SHA512 3b0c560cce673fa0e9506c18c4a25b56e26c8ccd7874098f55c37f1a556387b4c2d3ba81ef0368cc666178028eef0fd7beac6307588628c8c8c051381a21366f

dev-java/openjdk-jre-bin/openjdk-jre-bin-8.212_p03.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eapi7-ver java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jre_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
+		)"
+}
+
+MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
+SLOT="$(ver_cut 1)"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by AdoptOpenJDK"
+HOMEPAGE="https://adoptopenjdk.net"
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+
+IUSE="alsa cups +gentoo-vm headless-awt nsplugin selinux +webstart"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+PDEPEND="
+	webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
+	nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED}${dest#/}"
+
+	rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
+
+	# this does not exist on arm64 hence -f
+	rm -fv lib/*/libfreetype.so* || die
+
+	if ! use alsa ; then
+		rm -v lib/*/libjsoundalsa.so* || die
+	fi
+
+	if use headless-awt ; then
+		rm -fvr lib/*/lib*{[jx]awt,splashscreen}* \
+			bin/policytool || die
+	fi
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	use gentoo-vm && java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+
+	if use gentoo-vm ; then
+		ewarn "WARNING! You have enabled the gentoo-vm USE flag, making this JRE"
+		ewarn "recognised by the system. This will almost certainly break things."
+	else
+		ewarn "The experimental gentoo-vm USE flag has not been enabled so this JRE"
+		ewarn "will not be recognised by the system. For example, simply calling"
+		ewarn "\"java\" will launch a different JVM. This is necessary until Gentoo"
+		ewarn "fully supports OpenJDK 8. This JRE must therefore be invoked using its"
+		ewarn "absolute location under ${EPREFIX}/opt/${P}."
+	fi
+}