xfce-base/xfce4-panel: Bump to 4.18.4

Signed-off-by: Michał Górny <[email protected]>

xfce-base/xfce4-panel/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.18.3.tar.bz2 1452647 BLAKE2B 40545b13fa0b8d7178fc9753cb3b1b00b0729956155a1321ba7570f83d53eecc528ddaf47cb5653a25d9df1da45d9f586311426df75471c7a6c15f5b28dc6367 SHA512 d85a7540b11c4e9ed9c99b9660d12a14ae665c6c496dd0674dc4aa048d0f043dc3659a42af862ec9409d2181c3b0ae588750373530b4c9f42d4427e08e91de19
+DIST xfce4-panel-4.18.4.tar.bz2 1624451 BLAKE2B 73fdfe6bdca57a1f7954620f8cb6243660290ef105e2227274d7c6e3d4d6996aa4f97ec79c1c4e7e322cb0f24d7470bc8a7f2c283a7396ec340c6eb401bcc2ed SHA512 27ab96d9fc22c505763bf0b4ad4e2d0224638dc5b78202769caba2a07e1779a77ad0492341d1fe368fb47e30724fa797f74ff5e65138c819abdd1cd64fd8a1c2
 DIST xfce4-panel-4.19.1.tar.bz2 2087777 BLAKE2B 9be568832d6bc56fcecaf6eff2a907b64cc2b7f9fa51f18109c18300b9cb9cd7044d64b2b89d28ede409be3d4cd026274c543db7892ea128a1ce52679d62cccc SHA512 f22673e3a8785283a4179bf3a7791f2b14b9d5e87efffdc822ad61b24cca827517a15f0484392255ef04aeac99b5d4722bf347d14981340d4d86d7b47700883d

xfce-base/xfce4-panel/xfce4-panel-4.18.4.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-panel/start
+	https://gitlab.xfce.org/xfce/xfce4-panel/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbusmenu introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.66.0
+	>=x11-libs/cairo-1.16.0
+	>=x11-libs/gtk+-3.24.0:3[introspection?]
+	x11-libs/libX11
+	x11-libs/libwnck:3
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-4.17.0:=
+	>=xfce-base/libxfce4ui-4.17.1:=
+	>=xfce-base/libxfce4util-4.17.2:=[introspection?,vala?]
+	>=xfce-base/xfconf-4.13:=
+	dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
+	introspection? ( >=dev-libs/gobject-introspection-1.66:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-lang/perl
+	dev-util/gdbus-codegen
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable dbusmenu dbusmenu-gtk3)
+		$(use_enable vala)
+	)
+
+	use vala && vala_setup
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}