sci-mathematics/agda: fix dev-haskell/cpphs dependency

Package-Manager: portage-2.2.26
johu · Jan 13, 2016 · 48a5452 · 48a5452
1 parent 31b95fc
commit 48a5452
Showing 1 changed file with 119 additions and 0 deletions.
diff --git a/sci-mathematics/agda/agda-2.4.2.3-r3.ebuild b/sci-mathematics/agda/agda-2.4.2.3-r3.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# ebuild generated by hackport 0.4.5.9999
+
+CABAL_FEATURES="bin lib profile haddock hoogle hscolour"
+inherit haskell-cabal elisp-common
+
+MY_PN="Agda"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A dependently typed functional programming language and proof assistant"
+HOMEPAGE="http://wiki.portal.chalmers.se/agda/"
+SRC_URI="mirror://hackage/packages/archive/${MY_PN}/${PV}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="+cpphs +stdlib"
+
+RDEPEND=">=dev-haskell/base-orphans-0.3.1:=[profile?] <dev-haskell/base-orphans-0.5:=[profile?]
+	>=dev-haskell/binary-0.6:=[profile?] <dev-haskell/binary-0.8:=[profile?]
+	>=dev-haskell/boxes-0.1.3:=[profile?] <dev-haskell/boxes-0.2:=[profile?]
+	>=dev-haskell/data-hash-0.2.0.0:=[profile?] <dev-haskell/data-hash-0.3:=[profile?]
+	>=dev-haskell/edit-distance-0.2.1.2:=[profile?] <dev-haskell/edit-distance-0.3:=[profile?]
+	>=dev-haskell/equivalence-0.2.5:=[profile?] <dev-haskell/equivalence-0.4:=[profile?]
+	>=dev-haskell/geniplate-mirror-0.6.0.6:=[profile?] <dev-haskell/geniplate-mirror-0.8:=[profile?]
+	>=dev-haskell/haskeline-0.7:=[profile?] <dev-haskell/haskeline-0.8:=[profile?]
+	>=dev-haskell/haskell-src-exts-1.16.0.1:=[profile?] <dev-haskell/haskell-src-exts-1.17:=[profile?]
+	>=dev-haskell/old-time-1.1.0.0:=[profile?] <dev-haskell/old-time-1.2:=[profile?]
+	>=dev-haskell/parallel-3.2.0.4:=[profile?] <dev-haskell/parallel-3.3:=[profile?]
+	>=dev-haskell/quickcheck-2.8:2=[profile?] <dev-haskell/quickcheck-2.9:2=[profile?]
+	>=dev-haskell/strict-0.3.2:=[profile?] <dev-haskell/strict-0.4:=[profile?]
+	>=dev-haskell/text-0.11:=[profile?] <dev-haskell/text-1.3:=[profile?]
+	>=dev-haskell/transformers-compat-0.3.3.2:=[profile?] <dev-haskell/transformers-compat-0.5:=[profile?]
+	>=dev-haskell/unordered-containers-0.2:=[profile?] <dev-haskell/unordered-containers-0.3:=[profile?]
+	>=dev-haskell/xhtml-3000.2:=[profile?] <dev-haskell/xhtml-3000.3:=[profile?]
+	>=dev-haskell/zlib-0.4.0.1:=[profile?] <dev-haskell/zlib-0.7:=[profile?]
+	>=dev-lang/ghc-7.4.1:=
+	|| ( ( >=dev-haskell/hashable-1.1.2.3:=[profile?] <dev-haskell/hashable-1.2:=[profile?] )
+		( >=dev-haskell/hashable-1.2.1.0:=[profile?] <dev-haskell/hashable-1.3:=[profile?] ) )
+	|| ( ( >=dev-haskell/hashtables-1.0:=[profile?] <dev-haskell/hashtables-1.2:=[profile?] )
+		( >=dev-haskell/hashtables-1.2.0.2:=[profile?] <dev-haskell/hashtables-1.3:=[profile?] ) )
+	|| ( ( >=dev-haskell/mtl-2.1.1:=[profile?] <=dev-haskell/mtl-2.1.3.1:=[profile?] )
+		( >=dev-haskell/mtl-2.2.1:=[profile?] <dev-haskell/mtl-2.3:=[profile?] ) )
+	|| ( ( >=dev-haskell/transformers-0.3:=[profile?] <dev-haskell/transformers-0.4:=[profile?] )
+		( >=dev-haskell/transformers-0.4.1.0:=[profile?] <dev-haskell/transformers-0.5:=[profile?] ) )
+"
+RDEPEND+="
+		app-emacs/haskell-mode
+		virtual/emacs
+"
+PDEPEND="stdlib? ( =sci-mathematics/agda-stdlib-${PV} )"
+DEPEND="${RDEPEND}
+	dev-haskell/alex
+	>=dev-haskell/cabal-1.8
+	dev-haskell/happy
+	cpphs? ( >=dev-haskell/cpphs-1.19 <dev-haskell/cpphs-1.20 )
+"
+RDEPEND+="!sci-mathematics/agda-executable"
+
+SITEFILE="50${PN}2-gentoo.el"
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	cabal_chdeps \
+		'base-orphans >= 0.3.1 && < 0.4' 'base-orphans >= 0.3.1 && < 0.5' \
+		'data-hash == 0.2.0.0' 'data-hash >= 0.2.0.0 && < 0.3' \
+		'geniplate-mirror >= 0.6.0.6 && < 0.7' 'geniplate-mirror >= 0.6.0.6 && < 0.8'
+	sed -e '/.*emacs-mode.*$/d' \
+		-i "${S}/${MY_PN}.cabal" \
+		|| die "Could not remove agda-mode from ${MY_PN}.cabal"
+}
+
+src_configure() {
+	haskell-cabal_src_configure \
+		$(cabal_flag cpphs cpphs)
+}
+
+src_compile() {
+	BYTECOMPFLAGS="-L ./src/data/emacs-mode"
+	elisp-compile src/data/emacs-mode/*.el \
+		|| die "Failed to compile emacs mode"
+	haskell-cabal_src_compile
+}
+
+src_test() {
+	export LD_LIBRARY_PATH="${S}/dist/build${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
+
+	dist/build/agda/agda --test +RTS -M1g || die
+}
+
+src_install() {
+	local add="${ED}"/usr/share/"${P}/ghc-$(ghc-version)"
+
+	haskell-cabal_src_install
+
+	export LD_LIBRARY_PATH="${S}/dist/build${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
+	# generate Primitive.agdai, emulate Setup.hs postinst phase
+	Agda_datadir="${add}" \
+		"${ED}"/usr/bin/agda "${add}"/lib/prim/Agda/Primitive.agda \
+		|| die "Failed to build 'Primitive.agdai'"
+
+	elisp-install ${PN} src/data/emacs-mode/*.el \
+		|| die "Failed to install emacs mode"
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}" \
+		|| die "Failed to install elisp site file"
+}
+
+pkg_postinst() {
+	elisp-site-regen
+}
+
+pkg_postrm() {
+	elisp-site-regen
+}