dev-util/buildbot-worker: Version bump

Package-Manager: portage-2.3.0

dev-util/buildbot-worker/Manifest

@@ -1 +1,2 @@
 DIST buildbot-worker-0.9.0rc1.tar.gz 98041 SHA256 5fc9bc888aee3af5e144c51a6c11d8f5afe57e459644749c66b495e82fba7e7e SHA512 c9201649d8af74bc988032a69c20b220bf70b2fe7bba7eb27638408a34f2d82b90f6421a39f3a2af8cfbe8ea11429dc04faa1de635bff77fd5a9b13c9d78f167 WHIRLPOOL 6205a8bc018a65674e955fa6edeb9f32ec1f0dbc05bf50f649cab7271f506cfad61c8556a05c0d2185f364b9b9a493130bdea2e798cd96238f7b0797f6d12257
+DIST buildbot-worker-0.9.0rc2.tar.gz 95743 SHA256 12dd257a309b2af72cfc8e180bbcccf4fcd843786d5d2fb635967eef844682a6 SHA512 77773d06e86b03087215c045887f24f636ee7a3f9aafa59e3905f01fb3b7abee35308e25a7bec20cbf3cd5240db0569648f38413abdd5ca3b61f03c94bfc8801 WHIRLPOOL 8fa33af9e663e7f3b026a463d49707657dbaf8be0d57f5c47c9cdc4ca326aa5bbffb9589d1a0c8dc1c2be6cdc989c69e81ab69d29548c7d05dac08df6a352fff

dev-util/buildbot-worker/buildbot-worker-0.9.0_rc2.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+
+EGIT_REPO_URI="https://github.com/buildbot/buildbot.git"
+
+[[ ${PV} == *9999 ]] && inherit git-r3
+inherit readme.gentoo user distutils-r1
+
+DESCRIPTION="BuildBot Slave Daemon"
+HOMEPAGE="http://trac.buildbot.net/ http://code.google.com/p/buildbot/ http://pypi.python.org/pypi/buildbot-slave"
+
+MY_V="0.9.0rc2"
+MY_P="${PN}-${MY_V}"
+[[ ${PV} == *9999 ]] || SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+if [[ ${PV} == *9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64"
+fi
+IUSE="test"
+
+RDEPEND=">=dev-python/setuptools-21.2.1[${PYTHON_USEDEP}]
+	|| ( >=dev-python/twisted-core-8.0.0[${PYTHON_USEDEP}]
+		>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+	)
+	dev-python/future[${PYTHON_USEDEP}]
+	!<dev-util/buildbot-0.9.0_rc1"
+DEPEND="${RDEPEND}
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+[[ ${PV} == *9999 ]] && S=${S}/slave
+
+pkg_setup() {
+	enewuser buildbot
+
+	DOC_CONTENTS="The \"buildbot\" user and the \"buildbot_worker\" init script has been added
+		to support starting buildbot_worker through Gentoo's init system. To use this,
+		set up your build worker following the documentation, make sure the
+		resulting directories are owned by the \"buildbot\" user and point
+		\"${ROOT}etc/conf.d/buildbot_worker\" at the right location.  The scripts can
+		run as a different user if desired. If you need to run more than one
+		build worker, just copy the scripts."
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doman docs/buildbot-worker.1
+
+	newconfd "${FILESDIR}/buildbot_worker.confd" buildbot_worker
+	newinitd "${FILESDIR}/buildbot_worker.initd" buildbot_worker
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}